[arch-commits] Commit in latte-integrale/repos (2 files)

[Antonio Rojas]

    Date: Monday, June 21, 2021 @ 07:43:40
  Author: arojas
Revision: 966415

archrelease: copy trunk to community-staging-x86_64

Added:
  latte-integrale/repos/community-staging-x86_64/
  latte-integrale/repos/community-staging-x86_64/PKGBUILD
    (from rev 966414, latte-integrale/trunk/PKGBUILD)

----------+
 PKGBUILD |   30 ++++++++++++++++++++++++++++++
 1 file changed, 30 insertions(+)

Copied: latte-integrale/repos/community-staging-x86_64/PKGBUILD (from rev 966414, latte-integrale/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-06-21 07:43:40 UTC (rev 966415)
@@ -0,0 +1,30 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+
+pkgname=latte-integrale
+pkgver=1.7.6
+pkgrel=2
+pkgdesc='Computer software dedicated to the problems of counting lattice points and integration inside convex polytopes'
+arch=(x86_64)
+url='https://www.math.ucdavis.edu/~latte/'
+license=(GPL)
+depends=(4ti2 ntl cddlib lidia)
+source=(https://github.com/latte-int/latte/releases/download/version_${pkgver//./_}/latte-int-$pkgver.tar.gz)
+sha256sums=('006c10ebe5d5bfdc9b159cba6264a4432861fe763ce05fe821624ab7d3fc2170')
+
+build() {
+  cd latte-int-$pkgver
+
+  export CXXFLAGS+=" -std=c++14" # Fix build with GCC 11
+  ./configure --prefix=/usr --enable-shared --with-ntl=/usr
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool # Fix overlinking
+  make
+}
+
+package() {
+  cd latte-int-$pkgver
+  make DESTDIR="$pkgdir" install
+
+# Fix conflicts with LLVM
+  mv "$pkgdir"/usr/bin/{count,latte-count}
+}
+