[arch-commits] Commit in evolution-data-server/repos (2 files)

[Jan Steffens]

    Date: Monday, June 21, 2021 @ 07:50:49
  Author: heftig
Revision: 418535

archrelease: copy trunk to testing-x86_64

Added:
  evolution-data-server/repos/testing-x86_64/
  evolution-data-server/repos/testing-x86_64/PKGBUILD
    (from rev 418533, evolution-data-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: evolution-data-server/repos/testing-x86_64/PKGBUILD (from rev 418533, evolution-data-server/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-06-21 07:50:49 UTC (rev 418535)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evolution-data-server
+pkgver=3.40.2
+pkgrel=2
+pkgdesc="Centralized access to appointments and contacts"
+url="https://wiki.gnome.org/Apps/Evolution"
+arch=(x86_64)
+depends=(gnome-online-accounts nss krb5 libgweather libical db libgdata libphonenumber)
+makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake ninja)
+provides=(libcamel-1.2.so libebackend-1.2.so libebook-1.2.so libebook-contacts-1.2.so
+          libecal-2.0.so libedata-book-1.2.so libedata-cal-2.0.so libedataserver-1.2.so
+          libedataserverui-1.2.so)
+license=(GPL)
+_commit=f8f1acf0cb5d8fc2ac998d84a89f6ea18dc38f10  # tags/3.40.2^0
+source=("git+https://gitlab.gnome.org/GNOME/evolution-data-server.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # PrintableOptions.cmake: Correct variable name comparison
+  git cherry-pick -n c95a70bfeae25ba11fbe50fe759a6cdb29388e44
+}
+
+build() {
+  cmake -S $pkgname -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIBEXEC_INSTALL_DIR=/usr/lib \
+    -DSYSCONF_INSTALL_DIR=/etc \
+    -DENABLE_INTROSPECTION=ON \
+    -DENABLE_VALA_BINDINGS=ON \
+    -DENABLE_GTK_DOC=ON \
+    -DWITH_PHONENUMBER=ON
+  cmake --build build
+}
+
+check() {
+  # libedata-book tests fail because they try to
+  # mkdir /usr/lib/evolution-data-server/camel-providers
+  cmake --build build --target test || :
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}