[arch-commits] Commit in bemenu/repos (3 files)

[Christian Rebischke]

    Date: Thursday, June 24, 2021 @ 21:38:56
  Author: shibumi
Revision: 967222

archrelease: copy trunk to community-staging-x86_64

Added:
  bemenu/repos/community-staging-x86_64/
  bemenu/repos/community-staging-x86_64/PKGBUILD
    (from rev 967221, bemenu/trunk/PKGBUILD)
  bemenu/repos/community-staging-x86_64/bemenu-wayland.install
    (from rev 967221, bemenu/trunk/bemenu-wayland.install)

------------------------+
 PKGBUILD               |   77 +++++++++++++++++++++++++++++++++++++++++++++++
 bemenu-wayland.install |    8 ++++
 2 files changed, 85 insertions(+)

Copied: bemenu/repos/community-staging-x86_64/PKGBUILD (from rev 967221, bemenu/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-06-24 21:38:56 UTC (rev 967222)
@@ -0,0 +1,77 @@
+# Maintainer: Ivy Foster <iff at archlinux.org>
+# Maintainer: Christian Rebischke <chris.rebischke at archlinux.org>
+
+pkgbase=bemenu
+pkgname=(bemenu bemenu-ncurses bemenu-x11 bemenu-wayland)
+pkgver=0.6.2
+pkgrel=2
+
+# Wayland without wlroots is not supported.
+# https://github.com/Cloudef/bemenu/issues/79#issuecomment-572867783
+pkgdesc='Dynamic menu library and client program inspired by dmenu'
+url='https://github.com/Cloudef/bemenu'
+arch=(x86_64)
+license=(GPL3 LGPL3)
+
+makedepends=(libxinerama libxkbcommon ncurses pango wayland wayland-protocols wlroots)
+
+source=(
+	"bemenu-$pkgver.tar.gz::https://github.com/Cloudef/bemenu/archive/$pkgver.tar.gz"
+	"bemenu-$pkgver.tar.gz.asc::https://github.com/Cloudef/bemenu/releases/download/$pkgver/bemenu-$pkgver.tar.gz.asc"
+)
+# Checksums provided by packager
+sha256sums=('29e665ee6ba3afd8f0e0af7f351c2771816b11bad590fdd9364b5764e83e6d09'
+            'SKIP')
+validpgpkeys=('16B6B7CACAF339DECE9F154729317348D687B86B')
+
+build() {
+	cd "bemenu-$pkgver"
+	make PREFIX=/usr
+}
+
+# make test seems to have been removed with cmake
+#check() {
+#	cd "bemenu-$pkgver"
+#	make test
+#}
+
+package_bemenu() {
+	depends=(bemenu-renderer)
+	provides=(libbemenu)
+
+	cd "bemenu-$pkgver"
+	make DESTDIR="$pkgdir" PREFIX=/usr install
+	rm -rf "$pkgdir"/usr/lib/bemenu/
+}
+
+package_bemenu-ncurses() {
+	pkgdesc='ncurses renderer for bemenu'
+	provides=(bemenu-renderer)
+	depends=(libbemenu ncurses)
+
+	cd "bemenu-$pkgver"
+	make DESTDIR="$pkgdir" PREFIX=/usr install-renderers
+	rm -f "$pkgdir"/usr/lib/bemenu/bemenu-renderer-{wayland,x11}.so
+}
+
+package_bemenu-wayland() {
+	pkgdesc='Wayland (wlroots-based compositors) renderer for bemenu'
+	provides=(bemenu-renderer bemenu-wlroots)
+	depends=(libbemenu libxkbcommon pango wayland wayland-protocols)
+	replaces=(bemenu-wlroots)
+	install=bemenu-wayland.install
+
+	cd "bemenu-$pkgver"
+	make DESTDIR="$pkgdir" PREFIX=/usr install-renderers
+	rm -f "$pkgdir"/usr/lib/bemenu/bemenu-renderer-{curses,x11}.so
+}
+
+package_bemenu-x11() {
+	pkgdesc='X11 renderer for bemenu'
+	provides=(bemenu-renderer)
+	depends=(libbemenu libxinerama pango)
+
+	cd "bemenu-$pkgver"
+	make DESTDIR="$pkgdir" PREFIX=/usr install-renderers
+	rm -f "$pkgdir"/usr/lib/bemenu/bemenu-renderer-{curses,wayland}.so
+}

Copied: bemenu/repos/community-staging-x86_64/bemenu-wayland.install (from rev 967221, bemenu/trunk/bemenu-wayland.install)
===================================================================
--- community-staging-x86_64/bemenu-wayland.install	                        (rev 0)
+++ community-staging-x86_64/bemenu-wayland.install	2021-06-24 21:38:56 UTC (rev 967222)
@@ -0,0 +1,8 @@
+post_install() {
+	echo "Note: bemenu's wayland backend only works"
+	echo ' in compositors which implement wlr-layer-shell.'
+}
+
+post_upgrade() {
+	post_install
+}