[arch-commits] Commit in cgit-aurweb/repos (3 files)

[Christian Hesse]

    Date: Monday, June 28, 2021 @ 20:26:30
  Author: eworm
Revision: 967749

archrelease: copy trunk to community-testing-x86_64

Added:
  cgit-aurweb/repos/community-testing-x86_64/
  cgit-aurweb/repos/community-testing-x86_64/PKGBUILD
    (from rev 967748, cgit-aurweb/trunk/PKGBUILD)
  cgit-aurweb/repos/community-testing-x86_64/cgit.install
    (from rev 967748, cgit-aurweb/trunk/cgit.install)

--------------+
 PKGBUILD     |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 cgit.install |    5 +++++
 2 files changed, 59 insertions(+)

Copied: cgit-aurweb/repos/community-testing-x86_64/PKGBUILD (from rev 967748, cgit-aurweb/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-06-28 20:26:30 UTC (rev 967749)
@@ -0,0 +1,54 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Patrick Palka <patrick at parcs.ath.cx>
+# Contributor: Loui Chang <louipc.ist at gmail com>
+# Contributor: Andreas Baumann <abaumann at yahoo dot com>
+
+pkgname=cgit-aurweb
+pkgver=1.2.3
+_commit=be07e3bf163a719e29e7c181d3d77b18217119f4
+pkgrel=2
+pkgdesc="A web interface for git written in plain C (aurweb branch)"
+arch=('x86_64')
+url="https://git.zx2c4.com/cgit/"
+license=('GPL2')
+depends=('openssl' 'luajit')
+makedepends=('git' 'zlib' 'curl' 'asciidoc')
+optdepends=('groff: about page using man page syntax'
+	    'python-pygments: syntax highlighting support'
+	    'python-docutils: about page formatted with reStructuredText'
+	    'python-markdown: about page formatted with markdown'
+	    'gzip: gzip compressed snapshots'
+	    'bzip2: bzip2 compressed snapshots'
+	    'lzip: lzip compressed snapshots'
+	    'xz: xz compressed snapshots'
+	    'zstd: zstd compressed snapshots'
+	    'mime-types: serve file with correct content-type header')
+install=cgit.install
+source=("$pkgname::git+https://gitlab.archlinux.org/archlinux/cgit.git#commit=${_commit}")
+sha256sums=('SKIP')
+
+prepare() {
+	cd "$pkgname"
+
+	git submodule init
+	git submodule update
+}
+
+build() {
+	cd "$pkgname"
+
+	make
+	make doc-man
+}
+
+package() {
+	cd "$pkgname"
+	
+	make CGIT_SCRIPT_PATH="/usr/share/webapps/$pkgname" DESTDIR="$pkgdir" prefix=/usr filterdir="/usr/lib/$pkgname/filters" install
+	
+	install -vd "$pkgdir/var/cache/$pkgname"
+	mkdir -p "$pkgdir/usr/lib/$pkgname"
+	mv "$pkgdir/usr/share/webapps/$pkgname/cgit.cgi" "$pkgdir/usr/lib/$pkgname"
+	ln -sf ../../../lib/$pkgname/cgit.cgi "$pkgdir/usr/share/webapps/$pkgname/cgit.cgi"
+}

Copied: cgit-aurweb/repos/community-testing-x86_64/cgit.install (from rev 967748, cgit-aurweb/trunk/cgit.install)
===================================================================
--- community-testing-x86_64/cgit.install	                        (rev 0)
+++ community-testing-x86_64/cgit.install	2021-06-28 20:26:30 UTC (rev 967749)
@@ -0,0 +1,5 @@
+post_install() {
+	chown -v http:http var/cache/cgit-aurweb
+	echo "==> cgit looks at /etc/cgitrc for configuration. There is"
+	echo "==> an example configuration file in the cgitrc(5) man page."
+}