[arch-commits] Commit in stack/repos (4 files)

Felix Yan felixonmars at archlinux.org
Wed Mar 3 02:08:53 UTC 2021


    Date: Wednesday, March 3, 2021 @ 02:08:53
  Author: felixonmars
Revision: 878814

archrelease: copy trunk to community-staging-x86_64

Added:
  stack/repos/community-staging-x86_64/
  stack/repos/community-staging-x86_64/PKGBUILD
    (from rev 878813, stack/trunk/PKGBUILD)
  stack/repos/community-staging-x86_64/optparse-applicative-0.16.patch
    (from rev 878813, stack/trunk/optparse-applicative-0.16.patch)
  stack/repos/community-staging-x86_64/stack.install
    (from rev 878813, stack/trunk/stack.install)

---------------------------------+
 PKGBUILD                        |   81 ++++++++++++++++++++++++++++++++++++++
 optparse-applicative-0.16.patch |   25 +++++++++++
 stack.install                   |    4 +
 3 files changed, 110 insertions(+)

Copied: stack/repos/community-staging-x86_64/PKGBUILD (from rev 878813, stack/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-03-03 02:08:53 UTC (rev 878814)
@@ -0,0 +1,81 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=stack
+pkgver=2.5.1
+pkgrel=143
+pkgdesc="The Haskell Tool Stack"
+url="https://github.com/commercialhaskell/stack"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-annotated-wl-pprint' 'haskell-ansi-terminal'
+         'haskell-async' 'haskell-attoparsec' 'haskell-base64-bytestring' 'haskell-casa-client'
+         'haskell-casa-types' 'haskell-colour' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-cryptonite' 'haskell-cryptonite-conduit' 'haskell-echo'
+         'haskell-extra' 'haskell-file-embed' 'haskell-filelock' 'haskell-fsnotify'
+         'haskell-generic-deriving' 'haskell-githash' 'haskell-hackage-security' 'haskell-hashable'
+         'haskell-hi-file-parser' 'haskell-hpack' 'haskell-http-client' 'haskell-http-client-tls'
+         'haskell-http-conduit' 'haskell-http-download' 'haskell-http-types' 'haskell-memory'
+         'haskell-microlens' 'haskell-mintty' 'haskell-mono-traversable' 'haskell-mustache'
+         'haskell-neat-interpolation' 'haskell-network-uri' 'haskell-open-browser'
+         'haskell-optparse-applicative' 'haskell-optparse-generic' 'haskell-optparse-simple'
+         'haskell-pantry' 'haskell-path' 'haskell-path-io' 'haskell-persistent'
+         'haskell-persistent-sqlite' 'haskell-persistent-template' 'haskell-primitive'
+         'haskell-project-template' 'haskell-regex-applicative-text' 'haskell-retry' 'haskell-rio'
+         'haskell-rio-prettyprint' 'haskell-split' 'haskell-streaming-commons' 'haskell-tar'
+         'haskell-temporary' 'haskell-text-metrics' 'haskell-th-reify-many' 'haskell-tls'
+         'haskell-typed-process' 'haskell-unicode-transforms' 'haskell-unix-compat'
+         'haskell-unliftio' 'haskell-unordered-containers' 'haskell-vector' 'haskell-yaml'
+         'haskell-zip-archive' 'haskell-zlib')
+makedepends=('ghc' 'git' 'haskell-quickcheck' 'haskell-hspec' 'haskell-raw-strings-qq'
+             'haskell-smallcheck')
+checkdepends=('cabal-install')
+conflicts=('haskell-stack')
+replaces=('haskell-stack')
+install="stack.install"
+source=("git+https://github.com/commercialhaskell/stack.git#tag=v$pkgver"
+        optparse-applicative-0.16.patch)
+sha512sums=('SKIP'
+            '3ed61162edd869d5634e7e8485d784b9a192c97626da817635e6c756ca651454b5b806085aea6d7f8fd54041ae06e1613d9547958a85b777d2dfc35b02c0fbea')
+
+prepare() {
+  cd $pkgname
+  sed -i -e '/semigroups/d' $pkgname.cabal
+  sed -i '1i{-# LANGUAGE DataKinds #-}' src/Stack/Storage/User.hs src/Stack/Storage/Project.hs
+  patch -p1 -i ../optparse-applicative-0.16.patch
+}
+
+build() {
+  cd $pkgname
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+      -f-disable-git-info -f-integration-tests -f-static -f-hide-dependency-versions -f-supported-build \
+      --ghc-option='-pie'
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $pkgname
+  # cabal update
+  LD_LIBRARY_PATH="$PWD"/dist/build PATH="$PWD"/dist/build/stack:"$PATH" runhaskell Setup test
+  # Integration tests will result in 4 failures on Arch currently
+}
+
+package() {
+  cd $pkgname
+
+  install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+  install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+  runhaskell Setup copy --destdir="${pkgdir}"
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+
+  LD_PRELOAD=$(ls "$pkgdir"/usr/lib/libHSstack-*-ghc*.so) "${pkgdir}"/usr/bin/stack --bash-completion-script /usr/bin/stack > stack_completion_script
+  install -Dm644 stack_completion_script "${pkgdir}/usr/share/bash-completion/completions/stack"
+}

Copied: stack/repos/community-staging-x86_64/optparse-applicative-0.16.patch (from rev 878813, stack/trunk/optparse-applicative-0.16.patch)
===================================================================
--- community-staging-x86_64/optparse-applicative-0.16.patch	                        (rev 0)
+++ community-staging-x86_64/optparse-applicative-0.16.patch	2021-03-03 02:08:53 UTC (rev 878814)
@@ -0,0 +1,25 @@
+diff --git a/src/Options/Applicative/Builder/Extra.hs b/src/Options/Applicative/Builder/Extra.hs
+index d72e43af..c02dfd85 100644
+--- a/src/Options/Applicative/Builder/Extra.hs
++++ b/src/Options/Applicative/Builder/Extra.hs
+@@ -164,7 +164,7 @@ execExtraHelp args helpOpt parser pd =
+                                 some (strArgument (metavar "OTHER ARGUMENTS") :: Parser String)))
+                         (fullDesc <> progDesc pd))
+         return ()
+-  where hiddenHelper = abortOption ShowHelpText (long "help" <> hidden <> internal)
++  where hiddenHelper = abortOption (ShowHelpText Nothing) (long "help" <> hidden <> internal)
+ 
+ -- | 'option', specialized to 'Text'.
+ textOption :: Mod OptionFields Text -> Parser Text
+diff --git a/src/Options/Applicative/Complicated.hs b/src/Options/Applicative/Complicated.hs
+index a11bf51a..e78bd7ab 100644
+--- a/src/Options/Applicative/Complicated.hs
++++ b/src/Options/Applicative/Complicated.hs
+@@ -152,6 +152,6 @@ hsubparser' commandMetavar m = mkParser d g rdr
+ -- | Non-hidden help option.
+ helpOption :: Parser (a -> a)
+ helpOption =
+-    abortOption ShowHelpText $
++    abortOption (ShowHelpText Nothing) $
+     long "help" <>
+     help "Show this help text"

Copied: stack/repos/community-staging-x86_64/stack.install (from rev 878813, stack/trunk/stack.install)
===================================================================
--- community-staging-x86_64/stack.install	                        (rev 0)
+++ community-staging-x86_64/stack.install	2021-03-03 02:08:53 UTC (rev 878814)
@@ -0,0 +1,4 @@
+post_install() {
+  echo "You need to either 1) install latest stable ghc package from [community] or 2) install ncurses5-compat-libs from AUR for the prebuilt binaries installed by stack to work."
+}
+



More information about the arch-commits mailing list