[arch-commits] Commit in haskell-persistent-test/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Mar 6 12:25:31 UTC 2021


    Date: Saturday, March 6, 2021 @ 12:25:31
  Author: felixonmars
Revision: 884156

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent-test/repos/community-staging-x86_64/
  haskell-persistent-test/repos/community-staging-x86_64/PKGBUILD
    (from rev 884155, haskell-persistent-test/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-persistent-test/repos/community-staging-x86_64/PKGBUILD (from rev 884155, haskell-persistent-test/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-03-06 12:25:31 UTC (rev 884156)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=persistent-test
+pkgname=haskell-persistent-test
+pkgver=2.0.3.5
+pkgrel=67
+pkgdesc="Tests for Persistent"
+url="https://github.com/yesodweb/persistent"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-persistent' 'haskell-persistent-template' 'haskell-aeson'
+         'haskell-blaze-html' 'haskell-conduit' 'haskell-hspec'
+         'haskell-hspec-expectations' 'haskell-hunit' 'haskell-monad-control' 'haskell-monad-logger'
+         'haskell-path-pieces' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-random'
+         'haskell-resourcet' 'haskell-transformers-base' 'haskell-unliftio' 'haskell-unliftio-core'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('e4a4c4950ef4c8a0154e35574623c1137341c305bd25fdfa39c9cafa5a47f309a473fc53cda0d5118543cb8caf1826fb0e581a629448b7ae26d25a515099cfe8')
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list