[arch-commits] Commit in haskell-record-dot-preprocessor/repos (2 files)

[Felix Yan]

    Date: Friday, March 12, 2021 @ 06:17:40
  Author: felixonmars
Revision: 888268

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-record-dot-preprocessor/repos/community-staging-x86_64/
  haskell-record-dot-preprocessor/repos/community-staging-x86_64/PKGBUILD
    (from rev 888267, haskell-record-dot-preprocessor/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-record-dot-preprocessor/repos/community-staging-x86_64/PKGBUILD (from rev 888267, haskell-record-dot-preprocessor/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-03-12 06:17:40 UTC (rev 888268)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=record-dot-preprocessor
+pkgname=haskell-record-dot-preprocessor
+pkgver=0.2.9
+pkgrel=2
+pkgdesc="Preprocessor to allow record.field syntax"
+url="https://github.com/ndmitchell/record-dot-preprocessor#readme"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-extra' 'haskell-uniplate')
+makedepends=('ghc' 'haskell-record-hasfield')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('c04d00eddc3f2288fe7e4b4844e41133d91907c75eb973c785594e2ed5f420b11597ee8d4be110338a88bbb14fe62e9631926428ba8867adb1e2fe72113d1a4f')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}