[arch-commits] Commit in symengine/repos (2 files)
Antonio Rojas
arojas at archlinux.org
Sat Mar 13 08:56:26 UTC 2021
Date: Saturday, March 13, 2021 @ 08:56:25
Author: arojas
Revision: 890013
archrelease: copy trunk to community-staging-x86_64
Added:
symengine/repos/community-staging-x86_64/
symengine/repos/community-staging-x86_64/PKGBUILD
(from rev 890012, symengine/trunk/PKGBUILD)
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Copied: symengine/repos/community-staging-x86_64/PKGBUILD (from rev 890012, symengine/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2021-03-13 08:56:25 UTC (rev 890013)
@@ -0,0 +1,42 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Michael Schubert <mschu.dev at gmail>
+
+pkgname=symengine
+pkgver=0.7.0
+pkgrel=1
+pkgdesc="Fast symbolic manipulation library, written in C++"
+url="http://sympy.org/"
+arch=(x86_64)
+license=(MIT)
+depends=(arb libmpc gmp-ecm primesieve gperftools zlib)
+makedepends=(cmake boost llvm)
+source=(https://github.com/symengine/symengine/releases/download/v$pkgver/$pkgname-$pkgver.tar.gz)
+sha256sums=('8b865bb72b71539d9cd2488a0468c6c3ea90cc606062a7880c3ff5af6abd74b1')
+
+build() {
+ cmake -B build -S $pkgname-$pkgver \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DBUILD_SHARED_LIBS=ON \
+ -DWITH_TCMALLOC=ON \
+ -DWITH_PTHREAD=ON \
+ -DWITH_SYMENGINE_THREAD_SAFE=ON \
+ -DWITH_ARB=ON \
+ -DWITH_ECM=ON \
+ -DWITH_MPFR=ON \
+ -DWITH_MPC=ON \
+ -DWITH_LLVM=ON \
+ -DWITH_CPP14=ON \
+ -DWITH_PRIMESIEVE=ON \
+ -DWITH_BOOST=ON \
+ -DWITH_COTIRE=OFF
+ cmake --build build
+}
+
+check() {
+ cmake --build build --target test
+}
+
+package() {
+ DESTDIR="$pkgdir" cmake --install build
+ install -Dm644 $pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}
More information about the arch-commits
mailing list