[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, March 13, 2021 @ 15:29:08
  Author: felixonmars
Revision: 890313

addpkg: haskell-doctest-driver-gen 0.3.0.2-1

Added:
  haskell-doctest-driver-gen/
  haskell-doctest-driver-gen/repos/
  haskell-doctest-driver-gen/trunk/
  haskell-doctest-driver-gen/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: haskell-doctest-driver-gen/trunk/PKGBUILD
===================================================================
--- haskell-doctest-driver-gen/trunk/PKGBUILD	                        (rev 0)
+++ haskell-doctest-driver-gen/trunk/PKGBUILD	2021-03-13 15:29:08 UTC (rev 890313)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=doctest-driver-gen
+pkgname=haskell-doctest-driver-gen
+pkgver=0.3.0.2
+pkgrel=1
+pkgdesc="Generate driver file for doctest's cabal integration"
+url="https://github.com/Hexirp/doctest-driver-gen#readme"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs')
+makedepends=('ghc' 'uusi' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('5840c26d699339188e75ee0807778d1f011ea075f37a2a1c975ea1daae4b78f6')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -u base $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  LD_LIBRARY_PATH="$PWD/dist/build" runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  LD_LIBRARY_PATH="$PWD/dist/build" PATH="$PWD/dist/build/doctest-driver-gen:$PATH" runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}