[arch-commits] Commit in grpc/repos (3 files)
Felix Yan
felixonmars at archlinux.org
Sat Mar 13 22:48:36 UTC 2021
Date: Saturday, March 13, 2021 @ 22:48:36
Author: felixonmars
Revision: 890665
archrelease: copy trunk to community-staging-x86_64
Added:
grpc/repos/community-staging-x86_64/
grpc/repos/community-staging-x86_64/PKGBUILD
(from rev 890664, grpc/trunk/PKGBUILD)
grpc/repos/community-staging-x86_64/cmake-cli.patch
(from rev 890664, grpc/trunk/cmake-cli.patch)
-----------------+
PKGBUILD | 160 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
cmake-cli.patch | 57 +++++++++++++++++++
2 files changed, 217 insertions(+)
Copied: grpc/repos/community-staging-x86_64/PKGBUILD (from rev 890664, grpc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2021-03-13 22:48:36 UTC (rev 890665)
@@ -0,0 +1,160 @@
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Contributor: Aleksey Filippov <sarum9in at gmail.com>
+# Contributor: Victor Aurélio Santos <victoraur.santos at gmail.com>
+
+pkgbase='grpc'
+pkgname=('grpc' 'python-grpcio' 'php-grpc' 'php7-grpc' 'grpc-cli')
+pkgver=1.36.2
+_gtestver=c9ccac7cb7345901884aabf5d1a786cfa6e2f397
+_abseilcppver=20200923.2
+pkgrel=2
+pkgdesc="High performance, open source, general RPC framework that puts mobile and HTTP/2 first."
+arch=('x86_64')
+url='https://grpc.io'
+license=('BSD')
+makedepends=('re2' 're2c' 'protobuf' 'php' 'php7' 'c-ares' 'openssl' 'chrpath' 'cython'
+ 'cmake' 'benchmark' 'python-setuptools')
+source=("https://github.com/grpc/grpc/archive/v$pkgver/$pkgbase-$pkgver.tar.gz"
+ "https://github.com/google/googletest/archive/$_gtestver/googletest-$_gtestver.tar.gz"
+ "https://github.com/abseil/abseil-cpp/archive/$_abseilcppver/abseil-cpp-$_abseilcppver.tar.gz")
+sha256sums=('51403542b19e9ed5d3b6551ce4a828e17883a1593d4ca408b098f04b0767d202'
+ '443d383db648ebb8e391382c0ab63263b7091d03197f304390baac10f178a468'
+ 'bf3f13b13a0095d926b25640e060f7e13881bd8a792705dd9e161f3c2b9aa976')
+
+prepare() {
+ cd "$srcdir/$pkgbase-$pkgver"
+
+ ln -sf "$srcdir/googletest-$_gtestver/"{googlemock,googletest} \
+ third_party/googletest
+
+ rm -rf third_party/abseil-cpp
+ ln -s "$srcdir/abseil-cpp-$_abseilcppver/" third_party/abseil-cpp
+
+ mkdir build
+
+ cp -a src/php{,7}
+}
+
+build() {
+ cd "$srcdir/$pkgbase-$pkgver/build"
+ cmake \
+ -DCMAKE_BUILD_TYPE=None \
+ -DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG" \
+ -DgRPC_INSTALL=ON \
+ -DBUILD_SHARED_LIBS=ON \
+ -DgRPC_BUILD_TESTS=ON \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DgRPC_CARES_PROVIDER=package \
+ -DgRPC_PROTOBUF_PROVIDER=package \
+ -DgRPC_SSL_PROVIDER=package \
+ -DgRPC_ZLIB_PROVIDER=package \
+ -DgRPC_RE2_PROVIDER=package \
+ -DgRPC_BENCHMARK_PROVIDER=package \
+ ..
+
+ make
+ export LDFLAGS="$LDFLAGS -L$PWD"
+
+ # PHP
+ cd "$srcdir/$pkgbase-$pkgver/src/php/ext/$pkgbase"
+ phpize
+ ./configure --enable-grpc="$srcdir/$pkgbase-$pkgver"
+ make
+
+ # PHP7
+ cd "$srcdir/$pkgbase-$pkgver/src/php7/ext/$pkgbase"
+ phpize7
+ ./configure --enable-grpc="$srcdir/$pkgbase-$pkgver"
+ make
+
+ # Python
+ cd "$srcdir/$pkgbase-$pkgver"
+ GRPC_PYTHON_BUILD_WITH_CYTHON=1 \
+ GRPC_PYTHON_BUILD_SYSTEM_OPENSSL=1 \
+ GRPC_PYTHON_BUILD_SYSTEM_ZLIB=1 \
+ GRPC_PYTHON_BUILD_SYSTEM_CARES=1 \
+ GRPC_PYTHON_BUILD_SYSTEM_RE2=1 \
+ GRPC_BUILD_WITH_BORING_SSL_ASM=0 \
+ python setup.py build
+}
+
+package_grpc() {
+ depends=('c-ares' 'protobuf' 'openssl' 're2')
+ provides=(
+ 'libupb.so'
+ 'libgrpcpp_channelz.so'
+ 'libgrpc_unsecure.so'
+ 'libgrpc_plugin_support.so'
+ 'libgrpc.so'
+ 'libgrpc++_unsecure.so'
+ 'libgrpc++_reflection.so'
+ 'libgrpc++_error_details.so'
+ 'libgrpc++_alts.so'
+ 'libgrpc++.so'
+ 'libgpr.so'
+ 'libaddress_sorting.so'
+ )
+
+ cd "$srcdir/$pkgbase-$pkgver/build"
+ make DESTDIR="$pkgdir" install
+ install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python-grpcio() {
+ pkgdesc='Python language bindings for grpc, remote procedure call (RPC) framework'
+ depends=('c-ares' 'python' 're2')
+
+ cd "$srcdir/$pkgbase-$pkgver"
+ python setup.py install -O1 --skip-build --root="$pkgdir"
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_php-grpc() {
+ pkgdesc='gRPC module for PHP'
+ depends=('grpc' 'php')
+ backup=('etc/php/conf.d/grpc.ini')
+
+ # Install PHP extension.
+ cd "$srcdir/$pkgbase-$pkgver/src/php/ext/$pkgbase"
+ make install "INSTALL_ROOT=$pkgdir"
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+ # Remove RPATH
+ chrpath -d "$pkgdir/usr/lib/php/modules/grpc.so"
+
+ echo ';extension=grpc.so' >grpc.ini
+ install -Dm644 grpc.ini "$pkgdir/etc/php/conf.d/grpc.ini"
+}
+
+package_php7-grpc() {
+ pkgdesc='gRPC module for PHP'
+ depends=('grpc' 'php7')
+ backup=('etc/php7/conf.d/grpc.ini')
+
+ # Install PHP extension.
+ cd "$srcdir/$pkgbase-$pkgver/src/php7/ext/$pkgbase"
+ make install "INSTALL_ROOT=$pkgdir"
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+ # Remove RPATH
+ chrpath -d "$pkgdir/usr/lib/php7/modules/grpc.so"
+
+ echo ';extension=grpc.so' >grpc.ini
+ install -Dm644 grpc.ini "$pkgdir/etc/php7/conf.d/grpc.ini"
+}
+
+package_grpc-cli() {
+ pkgdesc='gRPC protocol buffers cli'
+ depends=('grpc')
+
+ cd "$srcdir/$pkgbase-$pkgver"
+ install -dm0755 "$pkgdir/usr/lib"
+ cp -a build/libgrpc++_test_config.so* "$pkgdir/usr/lib/"
+
+ for solib in build/third_party/abseil-cpp/absl/flags/*.so; do
+ install -t "$pkgdir/usr/lib" "$solib"
+ done
+
+ install -Dm0755 build/grpc_cli "$pkgdir/usr/bin/grpc_cli"
+ install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
Copied: grpc/repos/community-staging-x86_64/cmake-cli.patch (from rev 890664, grpc/trunk/cmake-cli.patch)
===================================================================
--- community-staging-x86_64/cmake-cli.patch (rev 0)
+++ community-staging-x86_64/cmake-cli.patch 2021-03-13 22:48:36 UTC (rev 890665)
@@ -0,0 +1,57 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index ef11396..dd10886 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -44,6 +44,7 @@ set(gRPC_INSTALL_CMAKEDIR "lib/cmake/${PACKAGE_NAME}" CACHE STRING "Installation
+ set(gRPC_INSTALL_SHAREDIR "share/grpc" CACHE STRING "Installation directory for root certificates")
+
+ # Options
++option(gRPC_BUILD_CLI "Build cli" ON)
+ option(gRPC_BUILD_TESTS "Build tests" OFF)
+ option(gRPC_BUILD_CODEGEN "Build codegen" ON)
+ option(gRPC_BUILD_CSHARP_EXT "Build C# extensions" ON)
+@@ -84,7 +85,7 @@ set_property(CACHE gRPC_PROTOBUF_PROVIDER PROPERTY STRINGS "module" "package")
+ set(gRPC_PROTOBUF_PACKAGE_TYPE "" CACHE STRING "Algorithm for searching protobuf package")
+ set_property(CACHE gRPC_PROTOBUF_PACKAGE_TYPE PROPERTY STRINGS "CONFIG" "MODULE")
+
+-if(gRPC_BUILD_TESTS)
++if(gRPC_BUILD_TESTS OR gRPC_BUILD_CLI)
+ set(gRPC_GFLAGS_PROVIDER "module" CACHE STRING "Provider of gflags library")
+ set_property(CACHE gRPC_GFLAGS_PROVIDER PROPERTY STRINGS "module" "package")
+
+@@ -4278,7 +4279,7 @@ target_link_libraries(b64_test
+
+
+ endif()
+-if(gRPC_BUILD_TESTS)
++if(gRPC_BUILD_TESTS OR gRPC_BUILD_CLI)
+
+ add_executable(bad_server_response_test
+ test/core/end2end/bad_server_response_test.cc
+@@ -4401,7 +4402,7 @@ target_link_libraries(bin_decoder_test
+
+
+ endif()
+-if(gRPC_BUILD_TESTS)
++if(gRPC_BUILD_TESTS OR gRPC_BUILD_CLI)
+
+ add_executable(bin_encoder_test
+ test/core/transport/chttp2/bin_encoder_test.cc
+@@ -5167,7 +5168,7 @@ target_link_libraries(fake_resolver_test
+
+
+ endif()
+-if(gRPC_BUILD_TESTS)
++if(gRPC_BUILD_TESTS OR gRPC_BUILD_CLI)
+
+ add_executable(fake_transport_security_test
+ test/core/tsi/fake_transport_security_test.cc
+@@ -10762,7 +10763,7 @@ target_link_libraries(global_config_test
+
+
+ endif()
+-if(gRPC_BUILD_TESTS)
++if(gRPC_BUILD_TESTS OR gRPC_BUILD_CLI)
+
+ add_executable(grpc_cli
+ ${_gRPC_PROTO_GENS_DIR}/src/proto/grpc/reflection/v1alpha/reflection.pb.cc
More information about the arch-commits
mailing list