[arch-commits] Commit in gitui/repos (2 files)

Levente Polyak anthraxx at archlinux.org
Sun Mar 14 13:11:55 UTC 2021


    Date: Sunday, March 14, 2021 @ 13:11:55
  Author: anthraxx
Revision: 891072

archrelease: copy trunk to community-testing-x86_64

Added:
  gitui/repos/community-testing-x86_64/
  gitui/repos/community-testing-x86_64/PKGBUILD
    (from rev 891071, gitui/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: gitui/repos/community-testing-x86_64/PKGBUILD (from rev 891071, gitui/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-03-14 13:11:55 UTC (rev 891072)
@@ -0,0 +1,35 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Simon Hauser <Simon-Hauser at outlook.de>
+# Contributor: Wesley Moore <wes at wezm.net>
+
+pkgname=gitui
+pkgver=0.12.0
+pkgrel=3
+pkgdesc='Blazing fast terminal-ui for git written in Rust'
+url='https://github.com/extrawurst/gitui'
+arch=('x86_64')
+license=('MIT')
+depends=('glibc' 'libgit2' 'libgit2.so' 'libxcb')
+makedepends=('cargo' 'python') # xcb crate needs python
+source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha256sums=('061536ecd2c9f9f52d4aecaece86e1e3c6fd1b88f25ce11483a783b800b9ec9e')
+b2sums=('822e0f441930fe585a35c098ee73cceb1b6d60dca8aef391d8cfa2264a302566e0830471be94f2a9ae8fefbb347dbf4bcc0cb787a48301e5abfa8767f32ad548')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  LIBGIT2_SYS_USE_PKG_CONFIG=1 cargo build --release --locked
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  LIBGIT2_SYS_USE_PKG_CONFIG=1 cargo test --release --locked
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dm 755 target/release/gitui -t "${pkgdir}/usr/bin/"
+  install -Dm 644 {KEY_CONFIG,README,THEMES}.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list