[arch-commits] Commit in ocrfeeder/repos (2 files)
Balló György
bgyorgy at archlinux.org
Sun Mar 14 20:24:51 UTC 2021
Date: Sunday, March 14, 2021 @ 20:24:51
Author: bgyorgy
Revision: 891301
archrelease: copy trunk to community-staging-any
Added:
ocrfeeder/repos/community-staging-any/
ocrfeeder/repos/community-staging-any/PKGBUILD
(from rev 891300, ocrfeeder/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: ocrfeeder/repos/community-staging-any/PKGBUILD (from rev 891300, ocrfeeder/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2021-03-14 20:24:51 UTC (rev 891301)
@@ -0,0 +1,52 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+
+pkgname=ocrfeeder
+pkgver=0.8.3
+pkgrel=4
+pkgdesc="GTK+ document layout analysis and optical character recognition application"
+arch=('any')
+url="https://wiki.gnome.org/Apps/OCRFeeder"
+license=('GPL')
+depends=('ghostscript' 'goocanvas' 'gtk3' 'gtkspell3' 'iso-codes' 'python-gobject' 'python-odfpy'
+ 'python-pillow' 'python-pyenchant' 'python-reportlab' 'python-sane' 'unpaper')
+makedepends=('git' 'gnome-common')
+optdepends=('tesseract: character recognition'
+ 'ocrad: character recognition'
+ 'gocr: character recognition'
+ 'cuneiform: character recognition')
+_commit=32967ef99e7524f0b98d92f88342d16446ee93bd # tags/0.8.3^0
+source=("git+https://gitlab.gnome.org/GNOME/ocrfeeder.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^release_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ # Remove the usage of deprecated 'xml.etree.ElementTree.Element.getchildren' (FS#69470)
+ git cherry-pick -n c0c460893961d5589f300645b32b5584a6c3f463
+
+ # Port to GooCanvas 3.0
+ sed -i "s/gi.require_version('GooCanvas', '2.0')/gi.require_version('GooCanvas', '3.0')/" src/ocrfeeder/studio/studioBuilder.py
+
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
+ make
+}
+
+check() {
+ make -C $pkgname check
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+ install -Dm644 resources/icons/org.gnome.OCRFeeder.svg "$pkgdir/usr/share/icons/hicolor/scalable/apps/org.gnome.OCRFeeder.svg"
+}
More information about the arch-commits
mailing list