[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Tuesday, March 16, 2021 @ 02:29:14
  Author: archange
Revision: 891707

Initial addition of python-smbprotocol to [community]

As fsspec opt/checkdepends.

Added:
  python-smbprotocol/
  python-smbprotocol/repos/
  python-smbprotocol/trunk/
  python-smbprotocol/trunk/PKGBUILD

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Added: python-smbprotocol/trunk/PKGBUILD
===================================================================
--- python-smbprotocol/trunk/PKGBUILD	                        (rev 0)
+++ python-smbprotocol/trunk/PKGBUILD	2021-03-16 02:29:14 UTC (rev 891707)
@@ -0,0 +1,34 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=smbprotocol
+pkgname=python-${_pkg}
+pkgver=1.4.0
+pkgrel=1
+pkgdesc="SMBv2 and v3 client"
+arch=(any)
+url="https://github.com/jborean93/smbprotocol"
+license=(MIT)
+depends=(python-cryptography python-pyspnego python-six)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest python-pytest-mock python-gssapi)
+optdepends=('python-gssapi: Kerberos support')
+# No tests in pypi tarball
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('f80ae1ba742f7336cc882914faa1ee65ef247278bf898b995cc0ecfeaa830847')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}
+  py.test -v
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+  install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}