[arch-commits] Commit in python-h5py/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Bruno Pagani]

    Date: Tuesday, March 16, 2021 @ 04:25:17
  Author: archange
Revision: 891720

archrelease: copy trunk to community-x86_64

Added:
  python-h5py/repos/community-x86_64/PKGBUILD
    (from rev 891719, python-h5py/trunk/PKGBUILD)
Deleted:
  python-h5py/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   93 +++++++++++++++++++++++++++++++------------------------------
 1 file changed, 48 insertions(+), 45 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-03-16 04:24:50 UTC (rev 891719)
+++ PKGBUILD	2021-03-16 04:25:17 UTC (rev 891720)
@@ -1,45 +0,0 @@
-# Maintainer: Felix Yan <felixonmars at archlinux.org>
-# Maintainer: Bruno Pagani <archange at archlinux.org>
-# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
-# Contributor: Rich Li <rich at dranek.com>
-# Contributor: Sebastien Binet <binet at lblbox>
-
-_pkg=h5py
-pkgname=python-${_pkg}
-pkgver=3.1.0
-pkgrel=3
-pkgdesc="General-purpose Python bindings for the HDF5 library"
-arch=(x86_64)
-url="https://www.h5py.org/"
-license=(BSD)
-depends=(hdf5 liblzf python-numpy)
-makedepends=(cython python-pkgconfig)
-checkdepends=(python-pytest python-pytest-mpi python-pytables)
-conflicts=(hdf5-openmpi)
-source=(https://files.pythonhosted.org/packages/source/h/${_pkg}/${_pkg}-${pkgver}.tar.gz)
-sha256sums=('1e2516f190652beedcb8c7acfa1c6fa92d99b42331cbef5e5c7ec2d65b0fc3c2')
-validpgpkeys=(AC47F71DB275ECD0B3DA46E857FA4540DD4EFCF7  # Thomas A Caswell (Brookhaven National Lab) <tcaswell at bnl.gov>
-              96B7334D7610EE3E68AFFE589E027116943D6A8B) # Thomas A Caswell <tcaswell at bnl.gov> (new key)
-# See https://github.com/h5py/h5py/issues/1299 about lack of GPG sigs for recent releases
-
-prepare() {
-  cd ${_pkg}-${pkgver}
-  # Remove RPATH
-  sed -i "s/settings\\['runtime_library_dirs'\\] = settings\\['library_dirs'\\]/pass/" setup_build.py
-}
-
-build() {
-  cd ${_pkg}-${pkgver}
-  H5PY_SYSTEM_LZF=1 python setup.py build
-}
-
-check() {
-  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
-  PYTHONPATH="${PWD}/${_pkg}-${pkgver}/build/lib.linux-${CARCH}-${python_version}" python -m pytest --pyargs h5py -rxXs
-}
-
-package() {
-  cd ${_pkg}-${pkgver}
-  python setup.py install --root="${pkgdir}" --skip-build --optimize=1
-  install -Dm644 licenses/license.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
-}

Copied: python-h5py/repos/community-x86_64/PKGBUILD (from rev 891719, python-h5py/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-03-16 04:25:17 UTC (rev 891720)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
+# Contributor: Rich Li <rich at dranek.com>
+# Contributor: Sebastien Binet <binet at lblbox>
+
+_pkg=h5py
+pkgname=python-${_pkg}
+pkgver=3.2.1
+pkgrel=1
+pkgdesc="General-purpose Python bindings for the HDF5 library"
+arch=(x86_64)
+url="https://www.h5py.org/"
+license=(BSD)
+depends=(hdf5 liblzf python-numpy)
+makedepends=(cython python-pkgconfig python-setuptools)
+checkdepends=(python-pytest python-pytest-mpi python-pytables)
+conflicts=(hdf5-openmpi)
+source=(https://files.pythonhosted.org/packages/source/h/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('89474be911bfcdb34cbf0d98b8ec48b578c27a89fdb1ae4ee7513f1ef8d9249e')
+validpgpkeys=(AC47F71DB275ECD0B3DA46E857FA4540DD4EFCF7  # Thomas A Caswell (Brookhaven National Lab) <tcaswell at bnl.gov>
+              96B7334D7610EE3E68AFFE589E027116943D6A8B) # Thomas A Caswell <tcaswell at bnl.gov> (new key)
+# See https://github.com/h5py/h5py/issues/1299 about lack of GPG sigs for recent releases
+
+prepare() {
+  cd ${_pkg}-${pkgver}
+  # Allow our numpy version
+  sed -i 's/numpy ==/numpy >=/g' setup.py
+  # Remove RPATH
+  sed -i "s/settings\\['runtime_library_dirs'\\] = settings\\['library_dirs'\\]/pass/" setup_build.py
+}
+
+build() {
+  cd ${_pkg}-${pkgver}
+  H5PY_SYSTEM_LZF=1 python setup.py build
+}
+
+check() {
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  export H5PY_TEST_CHECK_FILTERS=1
+  PYTHONPATH="${PWD}/${_pkg}-${pkgver}/build/lib.linux-${CARCH}-${python_version}" python -m pytest --pyargs h5py -rxXs
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --root="${pkgdir}" --skip-build --optimize=1
+  install -Dm644 licenses/license.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}