[arch-commits] Commit in (zimg zimg/trunk zimg/trunk/PKGBUILD)
Maxime Gauduin
alucryd at archlinux.org
Tue Mar 16 07:33:00 UTC 2021
Date: Tuesday, March 16, 2021 @ 07:32:59
Author: alucryd
Revision: 410026
move zimg from community to extra
Added:
zimg/
zimg/trunk/
zimg/trunk/PKGBUILD
----------+
PKGBUILD | 49 +++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 49 insertions(+)
Added: zimg/trunk/PKGBUILD
===================================================================
--- zimg/trunk/PKGBUILD (rev 0)
+++ zimg/trunk/PKGBUILD 2021-03-16 07:32:59 UTC (rev 410026)
@@ -0,0 +1,49 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+
+pkgname=zimg
+pkgver=3.0.1
+pkgrel=2
+pkgdesc='Scaling, colorspace conversion, and dithering library'
+arch=(x86_64)
+url=https://github.com/sekrit-twc/zimg
+license=(custom:WTFPL)
+depends=(
+ gcc-libs
+ glibc
+)
+makedepends=(git)
+provides=(libzimg.so)
+options=(!emptydirs)
+_tag=e17ee6cf72509c32c15067b32615849e69486367
+source=(git+https://github.com/sekrit-twc/zimg.git#tag=${_tag})
+sha256sums=(SKIP)
+
+pkgver() {
+ cd zimg
+
+ git describe --tags | sed 's/^release-//'
+}
+
+prepare() {
+ cd zimg
+
+ ./autogen.sh
+}
+
+build() {
+ cd zimg
+
+ ./configure \
+ --prefix=/usr \
+ --enable-x86simd \
+ --disable-static
+ make
+}
+
+package(){
+ make DESTDIR="${pkgdir}" -C zimg install
+ install -Dm 644 zimg/COPYING -t "${pkgdir}"/usr/share/licenses/zimg/
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list