[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Tuesday, March 16, 2021 @ 11:09:12
  Author: felixonmars
Revision: 891819

addpkg: haskell-svg-builder 0.1.1-1

Added:
  haskell-svg-builder/
  haskell-svg-builder/repos/
  haskell-svg-builder/trunk/
  haskell-svg-builder/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-svg-builder/trunk/PKGBUILD
===================================================================
--- haskell-svg-builder/trunk/PKGBUILD	                        (rev 0)
+++ haskell-svg-builder/trunk/PKGBUILD	2021-03-16 11:09:12 UTC (rev 891819)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=svg-builder
+pkgname=haskell-svg-builder
+pkgver=0.1.1
+pkgrel=1
+pkgdesc="DSL for building SVG."
+url="https://github.com/diagrams/svg-builder.git"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-builder' 'haskell-hashable' 'haskell-unordered-containers')
+makedepends=('ghc' 'uusi')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('4fd0e3f2cbc5601fc69e7eab41588cbfa1150dc508d9d86bf5f3d393880382cc')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -u base -u hashable $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}