[arch-commits] Commit in rhonabwy/repos (2 files)

[Maxime Gauduin]

    Date: Thursday, March 18, 2021 @ 08:39:52
  Author: alucryd
Revision: 894314

archrelease: copy trunk to community-staging-x86_64

Added:
  rhonabwy/repos/community-staging-x86_64/
  rhonabwy/repos/community-staging-x86_64/PKGBUILD
    (from rev 894313, rhonabwy/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: rhonabwy/repos/community-staging-x86_64/PKGBUILD (from rev 894313, rhonabwy/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-03-18 08:39:52 UTC (rev 894314)
@@ -0,0 +1,52 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=rhonabwy
+pkgver=0.9.99
+pkgrel=1
+pkgdesc='JWK, JWKS, JWS, JWE and JWT C library'
+arch=(x86_64)
+url=https://github.com/babelouest/rhonabwy
+license=(LGPL2.1)
+depends=(
+  glibc
+  gnutls
+  jansson
+  liborcania.so
+  libulfius.so
+  libyder.so
+  zlib
+)
+makedepends=(
+  cmake
+  doxygen
+  git
+  graphviz
+  ninja
+)
+provides=(librhonabwy.so)
+_tag=d439802e37931e1e456be0df29da5bab1056eef3
+source=(git+https://github.com/babelouest/rhonabwy.git#tag=${_tag})
+validpgpkeys=(8405B02FCC28EF9744C8F253FE82139440BD22B9) # Nicolas Mora <nicolas at babelouest.org>
+b2sums=(SKIP)
+
+pkgver() {
+  cd rhonabwy
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  export CFLAGS+=" -Wno-maybe-uninitialized"
+  cmake -S rhonabwy -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_RHONABWY_DOCUMENTATION=ON
+  ninja -C build doc
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -dm 755 "${pkgdir}"/usr/share/doc/rhonabwy
+  cp -dr --no-preserve=ownership rhonabwy/doc/html "${pkgdir}"/usr/share/doc/rhonabwy/
+}
+
+# vim: ts=2 sw=2 et: