[arch-commits] Commit in handbrake/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Thu Mar 18 11:15:46 UTC 2021
Date: Thursday, March 18, 2021 @ 11:15:45
Author: foutrelis
Revision: 894383
archrelease: copy trunk to community-staging-x86_64
Added:
handbrake/repos/community-staging-x86_64/
handbrake/repos/community-staging-x86_64/PKGBUILD
(from rev 894382, handbrake/trunk/PKGBUILD)
----------+
PKGBUILD | 63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 63 insertions(+)
Copied: handbrake/repos/community-staging-x86_64/PKGBUILD (from rev 894382, handbrake/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2021-03-18 11:15:45 UTC (rev 894383)
@@ -0,0 +1,63 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sebastien Piccand <sebcactus gmail com>
+
+pkgname=('handbrake' 'handbrake-cli')
+pkgver=1.3.3
+pkgrel=5
+arch=('x86_64')
+url="https://handbrake.fr/"
+license=('GPL')
+_commondeps=('libxml2' 'libass' 'libvorbis' 'opus' 'speex' 'libtheora' 'lame'
+ 'x264' 'jansson' 'libvpx' 'libva' 'numactl' 'bzip2' 'gcc-libs'
+ 'zlib' 'xz')
+_guideps=('gst-plugins-base' 'gtk3' 'librsvg' 'libgudev')
+makedepends=('intltool' 'python' 'nasm' 'wget' 'cmake' 'meson'
+ "${_commondeps[@]}" "${_guideps[@]}")
+source=(https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2{,.sig}
+ handbrake-fix-close-button-in-about-dialog.patch::https://github.com/HandBrake/HandBrake/commit/d3eb4a11ac.patch)
+sha256sums=('218a37d95f48b5e7cf285363d3ab16c314d97627a7a710cab3758902ae877f85'
+ 'SKIP'
+ '628451adc1341abf0917da86dcae7922c42b6e61225ef4b55182e8dbe74cfa49')
+validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers at handbrake.fr>
+
+prepare() {
+ cd "$srcdir/HandBrake-$pkgver"
+ patch -Np1 -i ../handbrake-fix-close-button-in-about-dialog.patch
+}
+
+build() {
+ cd "$srcdir/HandBrake-$pkgver"
+
+ ./configure \
+ --prefix=/usr \
+ --enable-qsv
+ make -C build
+}
+
+package_handbrake() {
+ pkgdesc="Multithreaded video transcoder"
+ depends=('desktop-file-utils' 'hicolor-icon-theme'
+ "${_commondeps[@]}" "${_guideps[@]}")
+ optdepends=('gst-plugins-good: for video previews'
+ 'gst-libav: for video previews'
+ 'intel-media-sdk: Intel QuickSync support'
+ 'libdvdcss: for decoding encrypted DVDs')
+
+ cd "$srcdir/HandBrake-$pkgver/build"
+
+ make DESTDIR="$pkgdir" install
+ rm "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+package_handbrake-cli() {
+ pkgdesc="Multithreaded video transcoder (CLI)"
+ depends=("${_commondeps[@]}")
+ optdepends=('intel-media-sdk: Intel QuickSync support'
+ 'libdvdcss: for decoding encrypted DVDs')
+
+ cd "$srcdir/HandBrake-$pkgver/build"
+ install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list