[arch-commits] Commit in lib32-libcaca/repos/multilib-x86_64 (PKGBUILD PKGBUILD)
Jan Steffens
heftig at archlinux.org
Thu Mar 18 16:05:57 UTC 2021
Date: Thursday, March 18, 2021 @ 16:05:56
Author: heftig
Revision: 894437
archrelease: copy trunk to multilib-x86_64
Added:
lib32-libcaca/repos/multilib-x86_64/PKGBUILD
(from rev 894436, lib32-libcaca/trunk/PKGBUILD)
Deleted:
lib32-libcaca/repos/multilib-x86_64/PKGBUILD
----------+
PKGBUILD | 112 ++++++++++++++++++++++++++++++++++++++-----------------------
1 file changed, 70 insertions(+), 42 deletions(-)
Deleted: PKGBUILD
===================================================================
--- PKGBUILD 2021-03-18 16:05:40 UTC (rev 894436)
+++ PKGBUILD 2021-03-18 16:05:56 UTC (rev 894437)
@@ -1,42 +0,0 @@
-# Maintainer: Felix Yan <felixonmars at archlinux.org>
-# Contributor: Limao Luo <luolimao+AUR at gmail.com>
-# Contributor: GordonGR <gordongr at freemail.gr>
-
-_pkgname=libcaca
-pkgname=lib32-$_pkgname
-pkgver=0.99.beta19
-pkgrel=2
-pkgdesc="Color AsCii Art library (32-bit)"
-arch=("x86_64")
-url="http://caca.zoy.org/wiki/libcaca"
-license=('custom:WTFPL')
-depends=("$_pkgname" "lib32-imlib2")
-source=("http://libcaca.zoy.org/files/$_pkgname/$_pkgname-$pkgver.tar.gz")
-md5sums=('a3d4441cdef488099f4a92f4c6c1da00')
-
-build() {
- export CC="gcc -m32"
- export CXX="g++ -m32"
- export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
-
- cd $_pkgname-$pkgver/
-
- ./configure \
- --prefix=/usr \
- --enable-shared \
- --disable-doc \
- --disable-cxx \
- --disable-gl \
- --disable-csharp \
- --disable-python \
- --disable-slang \
- --libdir=/usr/lib32/ \
- --libexecdir=/usr/lib32 \
- --host=i686-unknown-linux-gnu
- make
-}
-
-package() {
- make -C $_pkgname-$pkgver DESTDIR="$pkgdir" install
- rm -rf "$pkgdir"/usr/{bin,include,lib,share}/
-}
Copied: lib32-libcaca/repos/multilib-x86_64/PKGBUILD (from rev 894436, lib32-libcaca/trunk/PKGBUILD)
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2021-03-18 16:05:56 UTC (rev 894437)
@@ -0,0 +1,70 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Limao Luo <luolimao+AUR at gmail.com>
+# Contributor: GordonGR <gordongr at freemail.gr>
+
+pkgname=lib32-libcaca
+pkgver=0.99.beta19
+pkgrel=4
+pkgdesc="Color AsCii Art library (32-bit)"
+url="http://caca.zoy.org/wiki/libcaca"
+arch=(x86_64)
+license=(custom:WTFPL)
+depends=(lib32-imlib2 libcaca)
+makedepends=(git)
+_commit=caae67dce5d72ceceac79468bed47b58ea8e4a29 # tags/v0.99.beta19
+source=("git+https://github.com/cacalabs/libcaca#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd libcaca
+ git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+ cd libcaca
+
+ # CVE-2021-3410
+ # https://bugs.archlinux.org/task/70053
+ git cherry-pick -n 46b4ea7c e4968ba6
+
+ # Fix up version
+ sed -i '/^AC_INIT/s/beta19pre/beta19/;/^LT_MICRO=/s/18/19/' configure.ac
+
+ autoreconf -fvi
+}
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+ cd libcaca
+ ./configure \
+ --build=x86_64-pc-linux-gnu \
+ --prefix=/usr \
+ --libdir=/usr/lib32 \
+ --libexecdir=/usr/lib \
+ --mandir=/usr/share/man \
+ --enable-shared \
+ --disable-csharp \
+ --disable-cxx \
+ --disable-doc \
+ --disable-gl \
+ --disable-python \
+ --disable-slang \
+ --disable-static
+ make
+}
+
+package() {
+ cd libcaca
+ make DESTDIR="$pkgdir" install
+
+ rm -r "$pkgdir"/usr/{share,include}
+ find "$pkgdir/usr/bin" -type f -not -name caca-config -printf 'Removing %P\n' -delete
+ mv "$pkgdir"/usr/bin/caca-config{,-32}
+
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
+}
+
+# vim:set sw=2 noet:
More information about the arch-commits
mailing list