[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, March 18, 2021 @ 20:13:18
  Author: felixonmars
Revision: 894513

addpkg: haskell-hls-hlint-plugin 1.0.0.1-1

Added:
  haskell-hls-hlint-plugin/
  haskell-hls-hlint-plugin/repos/
  haskell-hls-hlint-plugin/trunk/
  haskell-hls-hlint-plugin/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: haskell-hls-hlint-plugin/trunk/PKGBUILD
===================================================================
--- haskell-hls-hlint-plugin/trunk/PKGBUILD	                        (rev 0)
+++ haskell-hls-hlint-plugin/trunk/PKGBUILD	2021-03-18 20:13:18 UTC (rev 894513)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-hlint-plugin
+pkgname=haskell-hls-hlint-plugin
+pkgver=1.0.0.1
+pkgrel=1
+pkgdesc="Hlint integration plugin with Haskell Language Server"
+url="https://hackage.haskell.org/package/hls-hlint-plugin"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-diff' 'haskell-aeson' 'haskell-apply-refact' 'haskell-data-default'
+         'haskell-extra' 'haskell-ghc' 'haskell-ghc-exactprint' 'haskell-ghcide' 'haskell-hashable'
+         'hlint' 'haskell-hls-plugin-api' 'haskell-hslogger' 'haskell-lens' 'haskell-lsp'
+         'haskell-regex-tdfa' 'haskell-shake' 'haskell-temporary' 'haskell-unordered-containers')
+makedepends=('ghc' 'uusi')
+#source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+source=("https://github.com/haskell/haskell-language-server/archive/ghcide-v1.1.0/haskell-language-server-ghcide-v1.1.0.tar.gz")
+sha256sums=('ec611943b46027488d85135eb61245ea7cbd892ed9825b1456a4b74e0eb5a713')
+
+prepare() {
+  cd haskell-language-server-ghcide-v1.1.0/plugins/$_hkgname
+  gen-setup
+}
+
+build() {
+  cd haskell-language-server-ghcide-v1.1.0/plugins/$_hkgname
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd haskell-language-server-ghcide-v1.1.0/plugins/$_hkgname
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}