[arch-commits] Commit in vlc/repos (4 files)

Maxime Gauduin alucryd at archlinux.org
Fri Mar 19 16:37:13 UTC 2021


    Date: Friday, March 19, 2021 @ 16:37:13
  Author: alucryd
Revision: 410315

archrelease: copy trunk to staging-x86_64

Added:
  vlc/repos/staging-x86_64/
  vlc/repos/staging-x86_64/PKGBUILD
    (from rev 410314, vlc/trunk/PKGBUILD)
  vlc/repos/staging-x86_64/update-vlc-plugin-cache.hook
    (from rev 410314, vlc/trunk/update-vlc-plugin-cache.hook)
  vlc/repos/staging-x86_64/vlc-3.0.11.1-srt_1.4.2.patch
    (from rev 410314, vlc/trunk/vlc-3.0.11.1-srt_1.4.2.patch)

------------------------------+
 PKGBUILD                     |  250 +++++++++++++++++++++++++++++++++++++++++
 update-vlc-plugin-cache.hook |   11 +
 vlc-3.0.11.1-srt_1.4.2.patch |   24 +++
 3 files changed, 285 insertions(+)

Copied: vlc/repos/staging-x86_64/PKGBUILD (from rev 410314, vlc/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-03-19 16:37:13 UTC (rev 410315)
@@ -0,0 +1,250 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sarah Hay <sarahhay at mb.sympatico.ca>
+# Contributor: Martin Sandsmark <martin.sandsmark at kde.org>
+
+pkgname=vlc
+_vlcver=3.0.12
+# optional fixup version including hyphen
+_vlcfixupver=
+pkgver=${_vlcver}${_vlcfixupver//-/.r}
+pkgrel=3
+pkgdesc='Multi-platform MPEG, VCD/DVD, and DivX player'
+url='https://www.videolan.org/vlc/'
+arch=('x86_64')
+license=('LGPL2.1' 'GPL2')
+depends=('a52dec' 'libdvbpsi' 'libxpm' 'libdca' 'libproxy' 'lua52' 'libidn'
+         'libmatroska' 'taglib' 'libmpcdec' 'ffmpeg' 'faad2' 'libmad'
+         'libmpeg2' 'xcb-util-keysyms' 'libtar' 'libxinerama' 'libsecret'
+         'libupnp' 'libixml.so' 'libupnp.so' 'libarchive' 'qt5-base'
+         'qt5-x11extras' 'qt5-svg' 'freetype2' 'fribidi' 'harfbuzz'
+         'fontconfig' 'libxml2' 'gnutls' 'libplacebo' 'wayland-protocols')
+makedepends=('gst-plugins-base-libs' 'live-media' 'libnotify' 'libbluray'
+             'flac' 'libdc1394' 'libavc1394' 'libcaca' 'gtk3'
+             'librsvg' 'libgme' 'xosd' 'twolame' 'aalib' 'avahi' 'systemd-libs'
+             'libmtp' 'libupnp' 'libmicrodns' 'libdvdcss' 'smbclient'
+             'vcdimager' 'libssh2' 'mesa' 'protobuf' 'libnfs' 'mpg123'
+             'libdvdread' 'libdvdnav' 'libogg' 'libshout' 'libmodplug' 'libvpx'
+             'libvorbis' 'speex' 'opus' 'libtheora' 'libpng' 'libjpeg-turbo'
+             'libx265.so' 'libx264.so' 'zvbi' 'libass' 'libkate' 'libtiger'
+             'sdl_image' 'libpulse' 'alsa-lib' 'jack' 'libsamplerate' 'libsoxr'
+             'lirc' 'libgoom2' 'projectm' 'chromaprint' 'aom' 'srt' 'dav1d'
+             'aribb24' 'aribb25' 'pcsclite')
+optdepends=('avahi: service discovery using bonjour protocol'
+            'aom: AOM AV1 codec'
+            'gst-plugins-base-libs: for libgst plugins'
+            'dav1d: dav1d AV1 decoder'
+            'libdvdcss: decoding encrypted DVDs'
+            'libavc1394: devices using the 1394ta AV/C'
+            'libdc1394: IEEE 1394 access plugin'
+            'kwallet: kwallet keystore'
+            'libva-vdpau-driver: vdpau backend nvidia'
+            'libva-intel-driver: video backend intel'
+            'libbluray: Blu-Ray video input'
+            'flac: Free Lossless Audio Codec plugin'
+            'twolame: TwoLAME mpeg2 encoder plugin'
+            'libgme: Game Music Emu plugin'
+            'vcdimager: navigate VCD with libvcdinfo'
+            'libmtp: MTP devices discovery'
+            'systemd-libs: udev services discovery'
+            'smbclient: SMB access plugin'
+            'libcdio: audio CD playback'
+            'gnu-free-fonts: subtitle font '
+            'ttf-dejavu: subtitle font'
+            'libssh2: sftp access'
+            'libnfs: NFS access'
+            'mpg123: mpg123 codec'
+            'protobuf: chromecast streaming'
+            'libmicrodns: mDNS services discovery (chromecast etc)'
+            'lua52-socket: http interface'
+            'live-media: RTSP input'
+            'libdvdread: DVD input module'
+            'libdvdnav: DVD with navigation input module'
+            'libogg: Ogg and OggSpots codec'
+            'libshout: shoutcast/icecast output plugin'
+            'libmodplug: MOD output plugin'
+            'libvpx: VP8 and VP9 codec'
+            'libvorbis: Vorbis decoder/encoder'
+            'speex: Speex codec'
+            'opus: opus codec'
+            'libtheora: theora codec'
+            'libpng: PNG support'
+            'libjpeg-turbo: JPEG support'
+            'librsvg: SVG plugin'
+            'x264: H264 encoding'
+            'x265: HEVC/H.265 encoder'
+            'zvbi: VBI/Teletext/webcam/v4l2 capture/decoding'
+            'libass: Subtitle support'
+            'libkate: Kate codec'
+            'libtiger: Tiger rendering for Kate streams'
+            'sdl_image: SDL image support'
+            'srt: SRT input/output plugin'
+            'aalib: ASCII art video output'
+            'libcaca: colored ASCII art video output'
+            'libpulse: PulseAudio audio output'
+            'alsa-lib: ALSA audio output'
+            'jack: jack audio server'
+            'libsamplerate: audio Resampler'
+            'libsoxr: SoX audio Resampler'
+            'chromaprint: Chromaprint audio fingerprinter'
+            'lirc: lirc control'
+            'libgoom2: Goom visualization'
+            'projectm: ProjectM visualisation'
+            'ncurses: ncurses interface'
+            'libnotify: notification plugin'
+            'gtk3: notification plugin'
+            'aribb24: aribsub support'
+            'aribb25: aribcam support'
+            'pcsclite: aribcam support')
+conflicts=('vlc-plugin')
+replaces=('vlc-plugin')
+options=('!emptydirs')
+source=(https://download.videolan.org/${pkgname}/${_vlcver}/${pkgname}-${_vlcver}${_vlcfixupver}.tar.xz{,.asc}
+        update-vlc-plugin-cache.hook
+        vlc-3.0.11.1-srt_1.4.2.patch)
+sha512sums=('ebec92bf732540be117551e94613747c53514ade7e280167c08400375738df9a01ee0e5d7c7733aca151a4f80f1c7163fd41318f2cc80b04a3201f0ba697e5df'
+            'SKIP'
+            'b247510ffeadfd439a5dadd170c91900b6cdb05b5ca00d38b1a17c720ffe5a9f75a32e0cb1af5ebefdf1c23c5acc53513ed983a736e8fa30dd8fad237ef49dd3'
+            '090c75878894f89184179f534da503a78234cf4f0f5af602873ea2ba6b68326afed71ef6160d1352bdd5c05e45b36bfcd23b7286d5111a900b7c11829642ae0d')
+validpgpkeys=('65F7C6B4206BD057A7EB73787180713BE58D1ADC') # VideoLAN Release Signing Key
+
+prepare() {
+  cd ${pkgname}-${_vlcver}
+  sed -e 's:truetype/ttf-dejavu:TTF:g' -i modules/visualization/projectm.cpp
+  sed -e 's|-Werror-implicit-function-declaration||g' -i configure
+  sed 's|whoami|echo builduser|g' -i configure
+  sed 's|hostname -f|echo arch|g' -i configure
+  local src
+  for src in "${source[@]}"; do
+    src="${src%%::*}"
+    src="${src##*/}"
+    [[ $src = *.patch ]] || continue
+    echo "Applying patch $src..."
+    patch -Np1 < "../$src"
+  done
+}
+
+build() {
+  cd ${pkgname}-${_vlcver}
+
+  export CFLAGS+=" -I/usr/include/samba-4.0"
+  export CPPFLAGS+=" -I/usr/include/samba-4.0"
+  export CXXFLAGS+=" -std=c++11"
+  # upstream doesn't support lua 5.4 yet: https://trac.videolan.org/vlc/ticket/25036
+  export LUAC=/usr/bin/luac5.2
+  export LUA_LIBS="$(pkg-config --libs lua5.2)"
+  export RCC=/usr/bin/rcc-qt5
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --with-kde-solid=/usr/share/solid/actions/ \
+    --disable-rpath \
+    --enable-nls \
+    --enable-archive \
+    --enable-live555 \
+    --enable-dc1394 \
+    --enable-dv1394 \
+    --enable-dvdread \
+    --enable-dvdnav \
+    --enable-bluray \
+    --disable-opencv \
+    --enable-smbclient \
+    --enable-sftp \
+    --enable-nfs \
+    --enable-realrtsp \
+    --enable-dvbpsi \
+    --enable-gme \
+    --enable-ogg \
+    --enable-shout \
+    --enable-matroska \
+    --enable-mod \
+    --enable-mpc \
+    --enable-mad \
+    --enable-mpg123 \
+    --enable-gst-decode \
+    --enable-avcodec \
+    --enable-libva \
+    --enable-avformat \
+    --enable-postproc \
+    --enable-faad \
+    --enable-vpx \
+    --enable-twolame \
+    --disable-fdkaac \
+    --enable-a52 \
+    --enable-dca \
+    --enable-flac \
+    --enable-libmpeg2 \
+    --enable-vorbis \
+    --enable-speex \
+    --enable-opus \
+    --enable-oggspots \
+    --disable-schroedinger \
+    --enable-png \
+    --enable-jpeg \
+    --enable-x264 \
+    --enable-x265 \
+    --enable-zvbi \
+    --enable-libass \
+    --enable-kate \
+    --enable-tiger \
+    --enable-vdpau \
+    --enable-wayland \
+    --enable-sdl-image \
+    --enable-freetype \
+    --enable-fribidi \
+    --enable-harfbuzz \
+    --enable-fontconfig \
+    --enable-svg \
+    --enable-svgdec \
+    --enable-aa \
+    --enable-caca \
+    --enable-pulse \
+    --enable-alsa \
+    --enable-jack \
+    --enable-samplerate \
+    --enable-soxr \
+    --enable-chromaprint \
+    --enable-chromecast \
+    --enable-qt \
+    --enable-skins2 \
+    --enable-libtar \
+    --enable-ncurses \
+    --enable-lirc \
+    --enable-goom \
+    --enable-projectm \
+    --enable-avahi \
+    --enable-mtp \
+    --enable-upnp \
+    --enable-microdns \
+    --enable-libxml2 \
+    --disable-libgcrypt \
+    --enable-gnutls \
+    --enable-taglib \
+    --enable-secret \
+    --enable-kwallet \
+    --disable-update-check \
+    --enable-notify \
+    --enable-libplacebo \
+    --enable-vlc \
+    --enable-aribsub \
+    --enable-aribcam \
+    --enable-aom \
+    --enable-srt \
+    --enable-dav1d
+  make
+}
+
+package() {
+  cd ${pkgname}-${_vlcver}
+
+  make DESTDIR="${pkgdir}" install
+
+  for res in 16 32 48 128 256; do
+    install -Dm 644 "${srcdir}/vlc-${_vlcver}/share/icons/${res}x${res}/vlc.png" \
+                     "${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
+  done
+  install -Dm 644 "${srcdir}/update-vlc-plugin-cache.hook" -t "${pkgdir}/usr/share/libalpm/hooks"
+}
+
+# vim: ts=2 sw=2 et:

Copied: vlc/repos/staging-x86_64/update-vlc-plugin-cache.hook (from rev 410314, vlc/trunk/update-vlc-plugin-cache.hook)
===================================================================
--- staging-x86_64/update-vlc-plugin-cache.hook	                        (rev 0)
+++ staging-x86_64/update-vlc-plugin-cache.hook	2021-03-19 16:37:13 UTC (rev 410315)
@@ -0,0 +1,11 @@
+[Trigger]
+Type = Path
+Operation = Install
+Operation = Upgrade
+Operation = Remove
+Target = usr/lib/vlc/plugins/*
+
+[Action]
+Description = Updating the vlc plugin cache...
+When = PostTransaction
+Exec = /usr/lib/vlc/vlc-cache-gen /usr/lib/vlc/plugins

Copied: vlc/repos/staging-x86_64/vlc-3.0.11.1-srt_1.4.2.patch (from rev 410314, vlc/trunk/vlc-3.0.11.1-srt_1.4.2.patch)
===================================================================
--- staging-x86_64/vlc-3.0.11.1-srt_1.4.2.patch	                        (rev 0)
+++ staging-x86_64/vlc-3.0.11.1-srt_1.4.2.patch	2021-03-19 16:37:13 UTC (rev 410315)
@@ -0,0 +1,24 @@
+diff -ruN a/modules/access/srt.c b/modules/access/srt.c
+--- a/modules/access/srt.c	2018-04-23 10:03:39.000000000 +0200
++++ b/modules/access/srt.c	2020-09-26 10:35:18.830149487 +0200
+@@ -165,7 +165,7 @@
+ 
+     /* Set latency */
+     i_latency = var_InheritInteger( p_stream, "latency" );
+-    srt_setsockopt( p_sys->sock, 0, SRTO_TSBPDDELAY,
++    srt_setsockopt( p_sys->sock, 0, SRTO_LATENCY,
+         &i_latency, sizeof( int ) );
+ 
+     psz_passphrase = var_InheritString( p_stream, "passphrase" );
+diff -ruN a/modules/access_output/srt.c b/modules/access_output/srt.c
+--- a/modules/access_output/srt.c	2018-04-06 11:22:51.000000000 +0200
++++ b/modules/access_output/srt.c	2020-09-26 10:35:03.386828120 +0200
+@@ -162,7 +162,7 @@
+ 
+     /* Set latency */
+     i_latency = var_InheritInteger( p_access, "latency" );
+-    srt_setsockopt( p_sys->sock, 0, SRTO_TSBPDDELAY,
++    srt_setsockopt( p_sys->sock, 0, SRTO_LATENCY,
+         &i_latency, sizeof( int ) );
+ 
+     if ( psz_passphrase != NULL && psz_passphrase[0] != '\0')



More information about the arch-commits mailing list