[arch-commits] Commit in ruby-minitest/repos (2 files)

[Felix Yan]

    Date: Friday, March 19, 2021 @ 17:32:14
  Author: felixonmars
Revision: 894771

archrelease: copy trunk to community-staging-any

Added:
  ruby-minitest/repos/community-staging-any/
  ruby-minitest/repos/community-staging-any/PKGBUILD
    (from rev 894770, ruby-minitest/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: ruby-minitest/repos/community-staging-any/PKGBUILD (from rev 894770, ruby-minitest/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-03-19 17:32:14 UTC (rev 894771)
@@ -0,0 +1,44 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Simon Kohlmeyer <simon.kohlmeyer at gmail.com>
+
+_gemname=minitest
+pkgname=ruby-${_gemname}
+_gitcommit=b8fb1014ad1932eddefb5107c0f6504ba45e0cbc
+pkgver=5.14.3
+pkgrel=2
+pkgdesc='Complete suite of testing facilities supporting TDD, BDD, mocking, and benchmarking'
+url='https://github.com/seattlerb/minitest'
+arch=('any')
+license=('MIT')
+depends=('ruby')
+makedepends=('git' 'rubygems' 'ruby-rake' 'ruby-rdoc' 'ruby-hoe')
+options=('!emptydirs')
+source=("git+https://github.com/seattlerb/minitest#commit=${_gitcommit}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${_gemname}
+  grep 'VERSION = "' lib/minitest.rb|sed -E 's|.*"(.+)".*|\1|'
+}
+
+build() {
+  cd ${_gemname}
+  rake gem
+}
+
+check() {
+  cd ${_gemname}
+  rake test
+}
+
+package() {
+  cd ${_gemname}
+  local _gemdir="$(gem env gemdir)"
+  gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" \
+    -n "${pkgdir}/usr/bin" pkg/${_gemname}-${pkgver}.gem
+  install -Dm 644 README.rdoc History.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  rm -r "${pkgdir}/${_gemdir}/cache"
+}
+
+# vim: ts=2 sw=2 et: