[arch-commits] Commit in asciidoctor/repos (2 files)

Felix Yan felixonmars at archlinux.org
Fri Mar 19 18:00:03 UTC 2021


    Date: Friday, March 19, 2021 @ 18:00:03
  Author: felixonmars
Revision: 894830

archrelease: copy trunk to community-staging-any

Added:
  asciidoctor/repos/community-staging-any/
  asciidoctor/repos/community-staging-any/PKGBUILD
    (from rev 894827, asciidoctor/trunk/PKGBUILD)

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Copied: asciidoctor/repos/community-staging-any/PKGBUILD (from rev 894827, asciidoctor/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2021-03-19 18:00:03 UTC (rev 894830)
@@ -0,0 +1,34 @@
+# Maintainer:  Christian Rebischke <chris.rebischke at archlinux.org>
+# Contributor: Stefan Tatschner <rumpelsepp at sevenbyte.org>
+# Contributor: Nick Østergaard <oe.nick at gmail dot com>
+# Contributor: Nicolas Bigaouette <nbigaouette at chemcomp.com>
+
+pkgname=asciidoctor
+pkgver=2.0.12
+pkgrel=2
+pkgdesc='An implementation of AsciiDoc in Ruby'
+arch=('any')
+url='https://asciidoctor.org'
+license=('MIT')
+makedepends=('ruby-rdoc')
+depends=('ruby')
+options=(!emptydirs)
+source=("https://rubygems.org/downloads/${pkgname}-${pkgver}.gem")
+noextract=("$pkgname-$pkgver.gem")
+sha512sums=('a927d052e4a2934524d8222700e83fbc746fa2b4880a810e39a579c1dff02054c83284a1c9e0af176709c0ab129677fcfcaa14c038ec124fb394852f38294db5')
+
+package() {
+    local _gemdir="$(ruby -e 'puts Gem.default_dir')"
+
+    gem install --ignore-dependencies --no-user-install --verbose \
+        -i "$pkgdir/$_gemdir" -n "$pkgdir/usr/bin" \
+        "$pkgname-$pkgver.gem"
+
+    install -Dm644 "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/LICENSE" \
+        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+    install -Dm644 "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/man/asciidoctor.1" \
+        "$pkgdir/usr/share/man/man1/asciidoctor.1"
+
+    rm "$pkgdir/$_gemdir/cache/$pkgname-$pkgver.gem"
+    rm -rf "$pkgdir/$_gemdir/gems/$pkgname-$pkgver/man"
+}



More information about the arch-commits mailing list