[arch-commits] Commit in gjs/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Jan Steffens
heftig at archlinux.org
Sun Mar 21 02:08:53 UTC 2021
Date: Sunday, March 21, 2021 @ 02:08:53
Author: heftig
Revision: 410399
archrelease: copy trunk to testing-x86_64
Added:
gjs/repos/testing-x86_64/
gjs/repos/testing-x86_64/PKGBUILD
(from rev 410398, gjs/trunk/PKGBUILD)
----------+
PKGBUILD | 44 ++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 44 insertions(+)
Copied: gjs/repos/testing-x86_64/PKGBUILD (from rev 410398, gjs/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2021-03-21 02:08:53 UTC (rev 410399)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gjs
+pkgver=1.68.0
+pkgrel=1
+epoch=2
+pkgdesc="Javascript Bindings for GNOME"
+url="https://wiki.gnome.org/Projects/Gjs"
+arch=(x86_64)
+license=(GPL)
+depends=(cairo gobject-introspection-runtime js78 dconf readline)
+makedepends=(gobject-introspection git meson dbus sysprof)
+checkdepends=(valgrind xorg-server-xvfb gtk3 gtk4)
+provides=(libgjs.so)
+_commit=87f0d0889127305ceb559c5451f29269d2f46f3b # tags/1.68.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gjs.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+}
+
+build() {
+ arch-meson $pkgname build \
+ --buildtype release \
+ -D installed_tests=false
+ meson compile -C build
+}
+
+check() {
+ xvfb-run -s '-screen 0 1920x1080x24 -nolisten local' \
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ depends+=(libreadline.so)
+ DESTDIR="$pkgdir" meson install -C build
+}
More information about the arch-commits
mailing list