[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, March 21, 2021 @ 21:53:29
  Author: felixonmars
Revision: 898532

addpkg: haskell-hls-retrie-plugin 1.0.0.1-1

Added:
  haskell-hls-retrie-plugin/
  haskell-hls-retrie-plugin/repos/
  haskell-hls-retrie-plugin/trunk/
  haskell-hls-retrie-plugin/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-hls-retrie-plugin/trunk/PKGBUILD
===================================================================
--- haskell-hls-retrie-plugin/trunk/PKGBUILD	                        (rev 0)
+++ haskell-hls-retrie-plugin/trunk/PKGBUILD	2021-03-21 21:53:29 UTC (rev 898532)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-retrie-plugin
+pkgname=haskell-hls-retrie-plugin
+pkgver=1.0.0.1
+pkgrel=1
+pkgdesc="Retrie integration plugin for Haskell Language Server"
+url="https://hackage.haskell.org/package/hls-retrie-plugin"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-extra' 'haskell-ghc' 'haskell-ghcide'
+         'haskell-hashable' 'haskell-hls-plugin-api' 'haskell-lsp' 'haskell-lsp-types'
+         'haskell-retrie' 'haskell-safe-exceptions' 'haskell-shake' 'haskell-unordered-containers')
+makedepends=('ghc' 'uusi')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('b87e280a52f179f247cdaed6b1c00883d7362b009f00088f9dc08a8ea0b5506f')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}