[arch-commits] Commit in (4 files)

[Antonio Rojas]

    Date: Tuesday, March 23, 2021 @ 07:40:55
  Author: arojas
Revision: 410750

community2extra: Moving qtkeychain from community to extra

Added:
  qtkeychain/
  qtkeychain/repos/
  qtkeychain/trunk/
  qtkeychain/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: qtkeychain/trunk/PKGBUILD
===================================================================
--- qtkeychain/trunk/PKGBUILD	                        (rev 0)
+++ qtkeychain/trunk/PKGBUILD	2021-03-23 07:40:55 UTC (rev 410750)
@@ -0,0 +1,47 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Kuba Serafinowski <zizzfizzix(at)gmail(dot)com>
+# Contributor: Teo Mrnjavac <teo at kde.org>
+
+pkgbase=qtkeychain
+pkgname=(qtkeychain-qt5 qtkeychain-qt6)
+pkgver=0.12.0
+pkgrel=1
+pkgdesc='Provides support for secure credentials storage'
+arch=(x86_64)
+url='https://github.com/frankosterfeld/qtkeychain'
+license=(BSD)
+depends=(libsecret)
+makedepends=(cmake qt5-tools qt6-tools)
+source=("$pkgname-$pkgver.tar.gz::https://github.com/frankosterfeld/qtkeychain/archive/v$pkgver.tar.gz")
+sha256sums=('cc547d58c1402f6724d3ff89e4ca83389d9e2bdcfd9ae3d695fcdffa50a625a8')
+
+build() {
+  cmake -B build-qt5 -S $pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib
+  cmake --build build-qt5
+
+  cmake -B build-qt6 -S $pkgbase-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_WITH_QT6=ON
+  cmake --build build-qt6
+}
+
+package_qtkeychain-qt5() {
+  depends+=(qt5-base)
+  optdepends=('kwallet: kwallet backend')
+  conflicts=(qtkeychain)
+  provides=(qtkeychain)
+  replaces=(qtkeychain)
+
+  DESTDIR="$pkgdir" cmake --install build-qt5
+  install -Dm644 $pkgbase-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_qtkeychain-qt6() {
+  depends+=(qt6-base)
+
+  DESTDIR="$pkgdir" cmake --install build-qt6
+  install -Dm644 $pkgbase-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}