[arch-commits] Commit in evolution-data-server/repos (2 files)

[Jan Steffens]

    Date: Wednesday, March 24, 2021 @ 20:14:18
  Author: heftig
Revision: 410862

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  evolution-data-server/repos/gnome-unstable-x86_64/
  evolution-data-server/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 410861, evolution-data-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: evolution-data-server/repos/gnome-unstable-x86_64/PKGBUILD (from rev 410861, evolution-data-server/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-03-24 20:14:18 UTC (rev 410862)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evolution-data-server
+pkgver=3.40.0
+pkgrel=1
+pkgdesc="Centralized access to appointments and contacts"
+url="https://wiki.gnome.org/Apps/Evolution"
+arch=(x86_64)
+depends=(gnome-online-accounts nss krb5 libgweather libical db libgdata libphonenumber)
+makedepends=(intltool gperf gobject-introspection vala gtk-doc boost git cmake ninja)
+provides=(libcamel-1.2.so libebackend-1.2.so libebook-1.2.so libebook-contacts-1.2.so
+          libecal-2.0.so libedata-book-1.2.so libedata-cal-2.0.so libedataserver-1.2.so
+          libedataserverui-1.2.so)
+license=(GPL)
+_commit=f045c3c894347f50dc9d58869f04a97803b7c13f  # tags/3.40.0^0
+source=("git+https://gitlab.gnome.org/GNOME/evolution-data-server.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^EVOLUTION_DATA_SERVER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  cmake -S $pkgname -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DLIBEXEC_INSTALL_DIR=/usr/lib \
+    -DSYSCONF_INSTALL_DIR=/etc \
+    -DENABLE_INTROSPECTION=ON \
+    -DENABLE_VALA_BINDINGS=ON \
+    -DENABLE_GTK_DOC=ON \
+    -DWITH_PHONENUMBER=ON
+  cmake --build build
+}
+
+check() {
+  # libedata-book tests fail because they try to
+  # mkdir /usr/lib/evolution-data-server/camel-providers
+  cmake --build build --target test || :
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}