[arch-commits] Commit in tepl/repos (2 files)
Jan Steffens
heftig at archlinux.org
Wed Mar 24 20:24:48 UTC 2021
Date: Wednesday, March 24, 2021 @ 20:24:48
Author: heftig
Revision: 410865
archrelease: copy trunk to gnome-unstable-x86_64
Added:
tepl/repos/gnome-unstable-x86_64/
tepl/repos/gnome-unstable-x86_64/PKGBUILD
(from rev 410864, tepl/trunk/PKGBUILD)
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Copied: tepl/repos/gnome-unstable-x86_64/PKGBUILD (from rev 410864, tepl/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD 2021-03-24 20:24:48 UTC (rev 410865)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Tobias Bohrmann (PlainTextField) <honeypot.carbage at aechelon.de>
+
+pkgname=tepl
+pkgver=6.00.0
+pkgrel=1
+pkgdesc="Library that eases the development of GtkSourceView-based text editors and IDEs"
+url="https://wiki.gnome.org/Projects/Tepl"
+arch=(x86_64)
+license=(LGPL3)
+depends=(amtk gtksourceview4 uchardet)
+makedepends=(gobject-introspection gtk-doc vala git meson)
+checkdepends=(xorg-server-xvfb)
+_commit=51b15258e130d2b5134f6cd5ff7f91c75e0a482a # tags/6.0.0.0^0
+source=("git+https://gitlab.gnome.org/GNOME/tepl.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ git tag -f 6.00.0 '6.0.0.0^0'; git tag -d 6.0.0.0 # Fixup tag
+}
+
+build() {
+ arch-meson $pkgname build -D gtk_doc=true
+ meson compile -C build
+}
+
+check() {
+ xvfb-run -s '-screen 0 1920x1080x24 -nolisten local' \
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ depends+=(libg{lib,object,io}-2.0.so libg{d,t}k-3.so libamtk-5.so
+ libgtksourceview-4.so)
+ provides+=("libtepl-${pkgver%%.*}.so")
+
+ DESTDIR="$pkgdir" meson install -C build
+}
More information about the arch-commits
mailing list