[arch-commits] Commit in lib32-expat/repos (2 files)
David Runge
dvzrv at archlinux.org
Thu Mar 25 18:54:51 UTC 2021
Date: Thursday, March 25, 2021 @ 18:54:51
Author: dvzrv
Revision: 903376
archrelease: copy trunk to multilib-staging-x86_64
Added:
lib32-expat/repos/multilib-staging-x86_64/
lib32-expat/repos/multilib-staging-x86_64/PKGBUILD
(from rev 903375, lib32-expat/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: lib32-expat/repos/multilib-staging-x86_64/PKGBUILD (from rev 903375, lib32-expat/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD (rev 0)
+++ multilib-staging-x86_64/PKGBUILD 2021-03-25 18:54:51 UTC (rev 903376)
@@ -0,0 +1,54 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+_name=expat
+pkgname=lib32-expat
+pkgver=2.3.0
+pkgrel=1
+pkgdesc='An XML Parser library'
+arch=(x86_64)
+url=https://libexpat.github.io/
+license=(MIT)
+depends=(
+ "expat=${pkgver}"
+ lib32-glibc
+)
+makedepends=(cmake)
+source=("https://github.com/libexpat/libexpat/releases/download/R_${pkgver//./_}/${_name}-${pkgver}.tar.bz2"{,.asc})
+sha512sums=('937468f2c298503a2c8d3f70b36e2c79d6b603e758abe0613fd2b636d3cf6906946776fdfe6725a8d6e90748ed7f7f07ad0d7a07c4328f6669bc89482c0e535b'
+ 'SKIP')
+b2sums=('cac52d8f67a1019985b5568ed1baf9adfda2366a67374fc1e97db0493b1e528805d916e33bd69ab34cd88debef05082a271534e475cfa22c11bff5157bbc70c2'
+ 'SKIP')
+validpgpkeys=(3176EF7DB2367F1FCA4F306B1F9B0E909AF37285) # Sebastian Pipping
+
+prepare() {
+ mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
+}
+build() {
+ cd "$pkgname-$pkgver"
+ export CC='gcc -m32'
+ export CXX='c++ -m32'
+ export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+ cmake -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=/usr/lib32 \
+ -DCMAKE_BUILD_TYPE='None' \
+ -W no-dev \
+ -B build \
+ -S .
+ make VERBOSE=1 -C build
+}
+
+check() {
+ cd "$pkgname-$pkgver"
+ make VERBOSE=1 -C build test
+}
+
+package() {
+ cd "$pkgname-$pkgver"
+ make VERBOSE=1 DESTDIR="$pkgdir" -C build install
+ install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname/"
+ rm -rf "${pkgdir}"/usr/{bin,include,share/man,share/doc}
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list