[arch-commits] Commit in gnome-remote-desktop/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Thursday, March 25, 2021 @ 22:35:22
  Author: heftig
Revision: 410992

archrelease: copy trunk to extra-x86_64

Added:
  gnome-remote-desktop/repos/extra-x86_64/PKGBUILD
    (from rev 410991, gnome-remote-desktop/trunk/PKGBUILD)
Deleted:
  gnome-remote-desktop/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  111 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 53 insertions(+), 58 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-03-25 22:35:16 UTC (rev 410991)
+++ PKGBUILD	2021-03-25 22:35:22 UTC (rev 410992)
@@ -1,58 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-
-pkgname=gnome-remote-desktop
-pkgver=0.1.9
-pkgrel=1
-pkgdesc="GNOME Remote Desktop server"
-url="https://wiki.gnome.org/Projects/Mutter/RemoteDesktop"
-arch=(x86_64)
-license=(GPL2)
-depends=(cairo freerdp glib2 pipewire systemd libvncserver libsecret libnotify dconf)
-makedepends=(git meson)
-checkdepends=(xorg-server-xvfb python-dbus python-gobject mutter)
-groups=(gnome)
-_commit=ba216dc82c7cdfcd2b99066b8be480e6a76cc60b  # tags/0.1.9^0
-source=("git+https://gitlab.gnome.org/GNOME/gnome-remote-desktop.git#commit=$_commit")
-sha256sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-
-  # Test fixes
-  sed -e 's|-noreset|& -nolisten local|' \
-      -e 's|dbus-run-session --||' \
-      -i tests/vnc-test-runner.sh
-}
-
-build() {
-  arch-meson $pkgname build
-  meson compile -C build
-}
-
-_run_tests() {
-  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
-  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/src}"
-  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
-
-  sed 's/exec pipewire-media-session .*/exec pipewire-media-session -d bluez5,alsa-seq,alsa-pcm/' \
-    </etc/pipewire/pipewire.conf >pipewire.conf
-  export PIPEWIRE_CONFIG_FILE="$PWD/pipewire.conf"
-
-  pipewire &
-  trap "kill $!; wait" EXIT
-
-  meson test -C build --print-errorlogs
-}
-
-check() {
-  dbus-run-session bash -c "$(declare -f _run_tests); _run_tests"
-}
-
-package() {
-  DESTDIR="$pkgdir" meson install -C build
-}

Copied: gnome-remote-desktop/repos/extra-x86_64/PKGBUILD (from rev 410991, gnome-remote-desktop/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-03-25 22:35:22 UTC (rev 410992)
@@ -0,0 +1,53 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=gnome-remote-desktop
+pkgver=40.0
+pkgrel=1
+pkgdesc="GNOME Remote Desktop server"
+url="https://wiki.gnome.org/Projects/Mutter/RemoteDesktop"
+arch=(x86_64)
+license=(GPL2)
+depends=(cairo freerdp glib2 pipewire systemd libvncserver libsecret libnotify
+         dconf fuse3 libxkbcommon)
+makedepends=(git meson)
+checkdepends=(xorg-server-xvfb python-dbus python-gobject mutter
+              pipewire-media-session)
+groups=(gnome)
+_commit=b64efe3e52cc334ac911f3ac967cd68afb907ae1  # tags/40.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-remote-desktop.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/src}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+  unset DBUS_SESSION_BUS_ADDRESS
+
+  pipewire &
+  _p1=$!
+
+  pipewire-media-session &
+  _p2=$!
+
+  trap "kill $_p1 $_p2; wait" EXIT
+
+  meson test -C build --print-errorlogs -t 2
+)
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}