[arch-commits] Commit in python-cryptography/repos (2 files)

[Felix Yan]

    Date: Friday, March 26, 2021 @ 03:20:34
  Author: felixonmars
Revision: 411055

archrelease: copy trunk to testing-x86_64

Added:
  python-cryptography/repos/testing-x86_64/
  python-cryptography/repos/testing-x86_64/PKGBUILD
    (from rev 411054, python-cryptography/trunk/PKGBUILD)

----------+
 PKGBUILD |   35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)

Copied: python-cryptography/repos/testing-x86_64/PKGBUILD (from rev 411054, python-cryptography/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-03-26 03:20:34 UTC (rev 411055)
@@ -0,0 +1,35 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=python-cryptography
+pkgver=3.4.7
+pkgrel=1
+pkgdesc="A package designed to expose cryptographic recipes and primitives to Python developers"
+arch=('x86_64')
+license=('Apache')
+url="https://pypi.python.org/pypi/cryptography"
+depends=('python-cffi')
+makedepends=('python-setuptools-rust')
+checkdepends=('python-pytest-runner' 'python-pytest-subtests' "python-cryptography-vectors=$pkgver"
+              'python-iso8601' 'python-pretend' 'python-hypothesis' 'python-pytz')
+source=("https://pypi.io/packages/source/c/cryptography/cryptography-$pkgver.tar.gz")
+sha512sums=('3c4cf64bc0b067ccdbb71efe04c32ac9d673faea6cc4ccd13d6b1b61920be4785806d19359b7657d032a2ff1c011a8b4f16ec4924d9df8a59d1a875a7f844473')
+
+prepare() {
+  # https://github.com/pyca/cryptography/pull/5777
+  sed -i '/install_requires/d' cryptography-$pkgver/setup.py
+}
+
+build() {
+  cd cryptography-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd cryptography-$pkgver
+  python setup.py pytest
+}
+
+package() {
+  cd cryptography-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}