[arch-commits] Commit in conky/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Levente Polyak]

    Date: Sunday, March 28, 2021 @ 01:13:08
  Author: anthraxx
Revision: 411140

archrelease: copy trunk to testing-x86_64

Added:
  conky/repos/testing-x86_64/
  conky/repos/testing-x86_64/PKGBUILD
    (from rev 411139, conky/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: conky/repos/testing-x86_64/PKGBUILD (from rev 411139, conky/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-03-28 01:13:08 UTC (rev 411140)
@@ -0,0 +1,63 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: James Rayner <james at archlinux.org>
+# Contributor: Partha Chowdhury <kira.laucas at gmail.com>
+
+pkgname=conky
+pkgver=1.12.1
+_gitcommit=7f84662c2c75dd939b27ce7d9fff95bc1070c1e0
+pkgrel=1
+pkgdesc='Lightweight system monitor for X'
+url='https://github.com/brndnmtthws/conky'
+license=('BSD' 'GPL')
+arch=('x86_64')
+makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git')
+depends=(
+  'glibc' 'glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft' 'imlib2'
+  'libxml2' 'libpulse' 'libxnvctrl' 'systemd-libs' 'ncurses' 'curl'
+  libncursesw.so libXNVCtrl.so libsystemd.so libpulse.so libcurl.so)
+source=("git+https://github.com/brndnmtthws/conky.git#commit=${_gitcommit}?signed")
+sha512sums=('SKIP')
+b2sums=('SKIP')
+validpgpkeys=(
+  'EB2E847572A71BE20F59AFBEB49ABB7270D9D4FD' # Brenden Matthews
+)
+
+pkgver() {
+  cd ${pkgname}
+  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd ${pkgname}
+  cmake \
+    -B build \
+    -D CMAKE_BUILD_TYPE=Release \
+    -D MAINTAINER_MODE=ON \
+    -D BUILD_DOCS=ON \
+    -D BUILD_WLAN=ON \
+    -D BUILD_XDBE=ON \
+    -D BUILD_XSHAPE=ON \
+    -D BUILD_IMLIB2=ON \
+    -D BUILD_CURL=ON \
+    -D BUILD_RSS=ON \
+    -D BUILD_NVIDIA=ON \
+    -D BUILD_WEATHER_METAR=ON \
+    -D BUILD_PULSEAUDIO=ON \
+    -D BUILD_JOURNAL=ON \
+    -D CMAKE_INSTALL_PREFIX=/usr \
+    -Wno-dev \
+    -S .
+
+  make -C build
+}
+
+package() {
+  cd ${pkgname}
+  make -C build DESTDIR="${pkgdir}" install
+  install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 extras/vim/syntax/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/syntax
+  install -Dm 644 extras/vim/ftdetect/conkyrc.vim -t "${pkgdir}"/usr/share/vim/vimfiles/ftdetect
+}
+
+# vim: ts=2 sw=2 et: