[arch-commits] Commit in haskell-tidal/repos (2 files)

[Felix Yan]

    Date: Monday, March 29, 2021 @ 04:29:52
  Author: felixonmars
Revision: 908410

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tidal/repos/community-staging-x86_64/
  haskell-tidal/repos/community-staging-x86_64/PKGBUILD
    (from rev 908409, haskell-tidal/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: haskell-tidal/repos/community-staging-x86_64/PKGBUILD (from rev 908409, haskell-tidal/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-03-29 04:29:52 UTC (rev 908410)
@@ -0,0 +1,55 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=Tidal
+pkgname=haskell-tidal
+pkgver=1.7.2
+pkgrel=6
+pkgdesc="A domain specific language for live coding pattern."
+arch=('x86_64')
+url="https://tidalcycles.org/"
+license=('GPL3')
+groups=('pro-audio')
+depends=('ghc' 'ghc-libs' 'glibc' 'haskell-bifunctors' 'haskell-clock'
+'haskell-colour' 'haskell-hosc' 'haskell-mwc-random' 'haskell-network'
+'haskell-primitive' 'haskell-random' 'haskell-vector' 'supercollider')
+checkdepends=('haskell-microspec')
+optdepends=('sc3-plugins: Examples using special UGens')
+conflicts=('tidalcycles')
+replaces=('tidalcycles')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/tidalcycles/${_name}/archive/v${pkgver}.tar.gz")
+sha512sums=('a5954ece7515801ff4948226a97a1428dc96b90c75942922bb355f654858273a34394aa6d2e3ab13787c87d7c793e40fec44283868fcbc5e7b80ef6844995300')
+b2sums=('a55206c3964ced9ad8f99044b4b112462f1674923c3c2ef41453680d5032cd5675ae109549c01f9d9fb19e3cc20a29ba91063aa577d99bc38313211a0b590b0c')
+
+prepare() {
+  mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup configure -O \
+                             --enable-shared \
+                             --enable-executable-dynamic \
+                             --disable-library-vanilla \
+                             --prefix=/usr \
+                             --docdir="/usr/share/doc/${pkgname}" \
+                             --enable-tests \
+                             --dynlibdir=/usr/lib \
+                             --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup test
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup copy --destdir="${pkgdir}"
+  install -vDm 744 register.sh "$pkgdir/usr/share/haskell/register/$pkgname.sh"
+  install -vDm 744 unregister.sh "$pkgdir/usr/share/haskell/unregister/$pkgname.sh"
+}