[arch-commits] Commit in podman/repos/community-x86_64 (PKGBUILD PKGBUILD)

Morten Linderud foxboron at archlinux.org
Wed Mar 31 14:49:22 UTC 2021


    Date: Wednesday, March 31, 2021 @ 14:49:22
  Author: foxboron
Revision: 910635

archrelease: copy trunk to community-x86_64

Added:
  podman/repos/community-x86_64/PKGBUILD
    (from rev 910634, podman/trunk/PKGBUILD)
Deleted:
  podman/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |  131 +++++++++++++++++++++++++++++++++----------------------------
 1 file changed, 72 insertions(+), 59 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-03-31 14:49:14 UTC (rev 910634)
+++ PKGBUILD	2021-03-31 14:49:22 UTC (rev 910635)
@@ -1,59 +0,0 @@
-# Maintainer: Morten Linderud <foxboron at archlinux.org>
-# Contributor: David Runge <dvzrv at archlinux.org>
-# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
-
-pkgbase=podman
-pkgname=(podman podman-docker)
-pkgver=3.0.1
-pkgrel=2
-pkgdesc='Tool and library for running OCI-based containers in pods'
-arch=(x86_64)
-url='https://github.com/containers/libpod'
-license=(Apache)
-depends=(cni-plugins conmon containers-common device-mapper iptables libseccomp
-runc slirp4netns libsystemd fuse-overlayfs)
-makedepends=(btrfs-progs go go-md2man git gpgme systemd)
-source=("git+$url#tag=v$pkgver?signed")
-validpgpkeys=('B7DBDCA456F7335E91F1C25CD3624C551D0515C4')
-sha256sums=('SKIP')
-
-pkgver() {
-  cd libpod
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-build() {
-  export BUILDTAGS='seccomp varlink systemd'
-  export CGO_CPPFLAGS="${CPPFLAGS}"
-  export CGO_CFLAGS="${CFLAGS}"
-  export CGO_CXXFLAGS="${CXXFLAGS}"
-  export CGO_LDFLAGS="${LDFLAGS}"
-  export GOFLAGS="-buildmode=pie -trimpath"
-
-  cd libpod
-  go generate ./pkg/varlink/...
-  make EXTRA_LDFLAGS='-s -w -linkmode=external'
-}
-
-package_podman() {
-  depends+=('libgpgme.so')
-  optdepends+=('podman-docker: for Docker-compatible CLI'
-              'btrfs-progs: support btrfs backend devices'
-              'catatonit: --init flag support'
-              'crun: support for unified cgroupsv2')
-
-  cd libpod
-  make install install.completions DESTDIR="$pkgdir" PREFIX=/usr
-  # remove man pages provided by containers-common
-  rm -rvf "${pkgdir}/usr/share/man/man5"
-}
-
-package_podman-docker() {
-  pkgdesc='Emulate Docker CLI using podman'
-  depends=(podman)
-  conflicts=(docker)
-  provides=(docker)
-
-  cd libpod
-  make install.docker DESTDIR="$pkgdir" PREFIX=/usr
-}

Copied: podman/repos/community-x86_64/PKGBUILD (from rev 910634, podman/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-03-31 14:49:22 UTC (rev 910635)
@@ -0,0 +1,72 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Contributor: David Runge <dvzrv at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+
+pkgbase=podman
+pkgname=(podman podman-docker)
+pkgver=3.1.0
+pkgrel=1
+pkgdesc='Tool and library for running OCI-based containers in pods'
+arch=(x86_64)
+url='https://github.com/containers/libpod'
+license=(Apache)
+depends=(cni-plugins conmon containers-common device-mapper iptables libseccomp
+runc slirp4netns libsystemd fuse-overlayfs)
+makedepends=(btrfs-progs go go-md2man git gpgme systemd)
+source=("git+$url#tag=v$pkgver?signed")
+validpgpkeys=('B7DBDCA456F7335E91F1C25CD3624C551D0515C4')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd libpod
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd libpod
+
+  # From
+  # Makefile: Fix make install.docker regression
+  # https://github.com/containers/podman/pull/9898
+
+  # Makefile: ensure install.docker creates BINDIR
+  git cherry-pick -n ab3b6df130f5ce21b126a666f5df3bd85aaf4c46
+
+  # Makefile: introduce install.docker-full
+  git cherry-pick -n 7801072851315cd1409d5d82a5e649659aa06b79
+}
+
+build() {
+  export BUILDTAGS='seccomp systemd'
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath"
+
+  cd libpod
+  make EXTRA_LDFLAGS='-s -w -linkmode=external'
+}
+
+package_podman() {
+  depends+=('libgpgme.so')
+  optdepends+=('podman-docker: for Docker-compatible CLI'
+              'btrfs-progs: support btrfs backend devices'
+              'catatonit: --init flag support'
+              'crun: support for unified cgroupsv2')
+
+  cd libpod
+  make install install.completions DESTDIR="$pkgdir" PREFIX=/usr
+  # remove man pages provided by containers-common
+  rm -rvf "${pkgdir}/usr/share/man/man5"
+}
+
+package_podman-docker() {
+  pkgdesc='Emulate Docker CLI using podman'
+  depends=(podman)
+  conflicts=(docker)
+  provides=(docker)
+
+  cd libpod
+  make -j1 install.docker-full DESTDIR="$pkgdir" PREFIX=/usr
+}



More information about the arch-commits mailing list