[arch-commits] Commit in gpg-tui/repos (community-x86_64 community-x86_64/PKGBUILD)

[Orhun Parmaksiz]

    Date: Monday, May 31, 2021 @ 10:39:06
  Author: orhun
Revision: 952049

archrelease: copy trunk to community-x86_64

Added:
  gpg-tui/repos/community-x86_64/
  gpg-tui/repos/community-x86_64/PKGBUILD
    (from rev 952048, gpg-tui/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: gpg-tui/repos/community-x86_64/PKGBUILD (from rev 952048, gpg-tui/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2021-05-31 10:39:06 UTC (rev 952049)
@@ -0,0 +1,42 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+
+pkgname=gpg-tui
+pkgver=0.1.4
+pkgrel=2
+pkgdesc="A terminal user interface for GnuPG"
+arch=('x86_64')
+url="https://github.com/orhun/gpg-tui"
+license=('MIT')
+depends=('libx11' 'gpgme')
+makedepends=('rust' 'python')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha512sums=('8911565dfa760149db6c187a1dc941bc7dbf726f5da85bf383c6fff11b0c0f7d1efeb6e8149e8820d90f3f07c86f349c94db90078785b56ad8f90d2497e023bf')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  mkdir completions/
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  cargo build --release --locked
+  OUT_DIR=completions/ cargo run --release --bin completions
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  cargo test --release --locked
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+  install -Dm 644 "man/$pkgname.1" -t "$pkgdir/usr/share/man/man1"
+  install -Dm 644 "completions/$pkgname.bash" "$pkgdir/usr/share/bash-completion/completions/$pkgname"
+  install -Dm 644 "completions/$pkgname.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d"
+  install -Dm 644 "completions/_$pkgname" -t "$pkgdir/usr/share/zsh/site-functions"
+}
+
+# vim: ts=2 sw=2 et: