[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, May 31, 2021 @ 14:07:53
  Author: felixonmars
Revision: 952802

addpkg: ocaml-ppx_derivers 1.2.1-5

Added:
  ocaml-ppx_derivers/
  ocaml-ppx_derivers/repos/
  ocaml-ppx_derivers/trunk/
  ocaml-ppx_derivers/trunk/PKGBUILD

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Added: ocaml-ppx_derivers/trunk/PKGBUILD
===================================================================
--- ocaml-ppx_derivers/trunk/PKGBUILD	                        (rev 0)
+++ ocaml-ppx_derivers/trunk/PKGBUILD	2021-05-31 14:07:53 UTC (rev 952802)
@@ -0,0 +1,36 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Peukert <dan.peukert at gmail.com>
+# Contributor: Jakob Gahde <j5lx at fmail.co.uk>
+
+_projectname='ppx_derivers'
+pkgname="ocaml-$_projectname"
+pkgver=1.2.1
+pkgrel=5
+pkgdesc='Shared deriving plugin registry'
+arch=('x86_64')
+url="https://github.com/ocaml-ppx/$_projectname"
+license=('BSD')
+depends=('ocaml')
+makedepends=('dune')
+options=('!strip')
+source=("$pkgname-$pkgver-$pkgrel.tar.gz::$url/archive/$pkgver.tar.gz")
+sha256sums=('b6595ee187dea792b31fc54a0e1524ab1e48bc6068d3066c45215a138cc73b95')
+
+_sourcedirectory="$_projectname-$pkgver"
+
+build() {
+	cd "$srcdir/$_sourcedirectory/"
+	dune build -p "$_projectname" --verbose
+}
+
+package() {
+	cd "$srcdir/$_sourcedirectory/"
+	DESTDIR="$pkgdir" dune install --prefix '/usr' --libdir 'lib/ocaml'
+
+	install -dm755 "$pkgdir/usr/share/doc/$pkgname"
+	mv "$pkgdir/usr/doc/$_projectname/"* "$pkgdir/usr/share/doc/$pkgname/"
+	rm -r "$pkgdir/usr/doc/"
+
+	install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
+	ln -sf "/usr/share/doc/$pkgname/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
+}