[arch-commits] Commit in alsa-utils/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[David Runge]

    Date: Monday, May 31, 2021 @ 17:46:00
  Author: dvzrv
Revision: 416893

archrelease: copy trunk to staging-x86_64

Added:
  alsa-utils/repos/staging-x86_64/
  alsa-utils/repos/staging-x86_64/PKGBUILD
    (from rev 416892, alsa-utils/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: alsa-utils/repos/staging-x86_64/PKGBUILD (from rev 416892, alsa-utils/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-05-31 17:46:00 UTC (rev 416893)
@@ -0,0 +1,48 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+# Contributor: judd <jvinet at zeroflux.org>
+
+pkgname=alsa-utils
+pkgver=1.2.5
+pkgrel=1
+pkgdesc="Advanced Linux Sound Architecture - Utilities"
+arch=('x86_64')
+url="https://www.alsa-project.org"
+license=('GPL2')
+depends=('glibc' 'pciutils' 'psmisc')
+makedepends=('alsa-lib' 'docbook-xsl' 'fftw' 'libsamplerate' 'ncurses'
+'python-docutils' 'systemd' 'xmlto')
+optdepends=('fftw: for alsabat')
+# we require /var/lib/alsa for state file
+options=(emptydirs)
+source=("https://www.alsa-project.org/files/pub/utils/${pkgname}-${pkgver}.tar.bz2"{,.sig})
+sha512sums=('0e319e553c9c209a46f5c83c50007bd82acf1c9cf78649978b3ab6fbb4349f51c1c7c6a975a8c24d25ba07ad5325e74d2c34dc5c89180998a0f63d1326fde8b1'
+            'SKIP')
+b2sums=('52cbe978390e1b5600bf7422e67ece1d24a946d99acddbc059bf6eb3a0b8dfe37cc573167013296e923bf1597973eb55b2580eaf849e088822ba7b2afc14279f'
+        'SKIP')
+validpgpkeys=('F04DF50737AC1A884C4B3D718380596DA6E59C91') # ALSA Release Team (Package Signing Key v1) <release at alsa-project.org>
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  autoreconf -vfi
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  ./configure --prefix=/usr \
+              --disable-alsaconf \
+              --sbindir=/usr/bin \
+              --with-udev-rules-dir=/usr/lib/udev/rules.d \
+              --with-systemdsystemunitdir=/usr/lib/systemd/system
+  make
+}
+
+package() {
+  depends+=('libasound.so' 'libatopology.so' 'libformw.so' 'libmenuw.so'
+  'libncursesw.so' 'libpanelw.so' 'libsamplerate.so')
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+  install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  # dir where to save ALSA state
+  install -d "${pkgdir}/var/lib/alsa"
+}