[arch-commits] Commit in taskell/repos (2 files)

[Felix Yan]

    Date: Saturday, May 1, 2021 @ 09:12:58
  Author: felixonmars
Revision: 925448

archrelease: copy trunk to community-staging-x86_64

Added:
  taskell/repos/community-staging-x86_64/
  taskell/repos/community-staging-x86_64/PKGBUILD
    (from rev 925447, taskell/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: taskell/repos/community-staging-x86_64/PKGBUILD (from rev 925447, taskell/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-01 09:12:58 UTC (rev 925448)
@@ -0,0 +1,44 @@
+# Maintainer: Jelle van der Waa <jelle at archlinux.org
+
+pkgname=taskell
+pkgver=1.11.0
+pkgrel=7
+pkgdesc='A command-line kanban board/task manager'
+license=(BSD)
+arch=(x86_64)
+url="https://hackage.haskell.org/package/$pkgname"
+depends=(ghc-libs haskell-aeson haskell-attoparsec haskell-brick haskell-config-ini haskell-file-embed haskell-fold-debounce haskell-http-client haskell-http-conduit haskell-http-types haskell-lens haskell-tz haskell-vty haskell-classy-prelude)
+makedepends=(ghc haskell-classy-prelude haskell-raw-strings-qq haskell-tasty haskell-tasty-discover haskell-tasty-expected-failure haskell-tasty-hunit)
+source=(https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz)
+sha512sums=('89eb3c87e8f74c9719e87fb2303fd66bd0133ba0414f109282b29511b8b5e7efc51f8a263be769892012ac46857a4945e73bb544f4e75c55ef0d72ed05845878')
+
+build() {
+  cd $pkgname-$pkgver
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --datasubdir=$pkgname \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $pkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $pkgname-$pkgver
+  runghc Setup.hs copy --destdir="$pkgdir"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+  # Doc only contains the license
+  rm -rf "$pkgdir/usr/share/doc"
+}
+
+# vim: ts=2 sw=2 et: