[arch-commits] Commit in haskell-yesod-persistent/repos (2 files)

[Felix Yan]

    Date: Saturday, May 1, 2021 @ 16:06:11
  Author: felixonmars
Revision: 925943

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-persistent/repos/community-staging-x86_64/
  haskell-yesod-persistent/repos/community-staging-x86_64/PKGBUILD
    (from rev 925942, haskell-yesod-persistent/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-yesod-persistent/repos/community-staging-x86_64/PKGBUILD (from rev 925942, haskell-yesod-persistent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-01 16:06:11 UTC (rev 925943)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod-persistent
+pkgname=haskell-yesod-persistent
+pkgver=1.6.0.6
+pkgrel=16
+pkgdesc="Some helpers for using Persistent from Yesod."
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-blaze-builder" "haskell-conduit" "haskell-persistent"
+         "haskell-resource-pool" "haskell-resourcet" "haskell-yesod-core")
+makedepends=('ghc' 'uusi' 'haskell-hspec' 'haskell-wai-extra' 'haskell-persistent-sqlite')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('2b6a7e5d8c8c6ab99b19b18dd8ae8c41a5e5218ed8eb376416c13c25f20ce00f184019a12e66c4aa8d231889f64fa8db21cacbebbdc705bc6058204190fab123')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -d persistent-template $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}