[arch-commits] Commit in haskell-monoid-subclasses/repos (2 files)

[Felix Yan]

    Date: Monday, May 3, 2021 @ 01:00:39
  Author: felixonmars
Revision: 926422

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-monoid-subclasses/repos/community-staging-x86_64/
  haskell-monoid-subclasses/repos/community-staging-x86_64/PKGBUILD
    (from rev 926421, haskell-monoid-subclasses/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-monoid-subclasses/repos/community-staging-x86_64/PKGBUILD (from rev 926421, haskell-monoid-subclasses/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-03 01:00:39 UTC (rev 926422)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+
+_hkgname=monoid-subclasses
+pkgname=haskell-monoid-subclasses
+pkgver=1.1
+pkgrel=13
+pkgdesc="Subclasses of Monoid"
+url="https://github.com/blamario/monoid-subclasses/"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-primes' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-tasty'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('08e2890801b30eeeaac5d9b7d23feeb5087a389ee29b73ef11c555f14c1e0c56844d25d3343cf9bda80e365f2ec290c452ded8a66c46b9ea61b62eb71d2563f4')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "BSD3-LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/BSD3-LICENSE.txt"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/BSD3-LICENSE.txt"
+}