[arch-commits] Commit in inkscape/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Monday, May 3, 2021 @ 12:38:03
  Author: felixonmars
Revision: 414231

archrelease: copy trunk to staging-x86_64

Added:
  inkscape/repos/staging-x86_64/
  inkscape/repos/staging-x86_64/PKGBUILD
    (from rev 414230, inkscape/trunk/PKGBUILD)

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

Copied: inkscape/repos/staging-x86_64/PKGBUILD (from rev 414230, inkscape/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-05-03 12:38:03 UTC (rev 414231)
@@ -0,0 +1,72 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Tobias Kieslich <tobias at justdreams.de>
+# Contributor: tobias <tobias at archlinux.org>
+
+pkgname=inkscape
+pkgver=1.0.2
+_commit=e86c870879310bfb4a9abee3e7fd65aef0408fd7
+pkgrel=6
+pkgdesc='Professional vector graphics editor'
+url='https://inkscape.org/'
+license=('GPL' 'LGPL')
+arch=('x86_64')
+makedepends=('cmake' 'boost' 'git')
+
+depends=(
+	'aspell'
+	'dbus-glib'
+	'double-conversion'
+	'gc'
+	'gdl'
+	'gsl'
+	'gtkmm3'
+	'gtkspell3'
+	'libcdr'
+	'libjpeg-turbo'
+	'graphicsmagick'
+	'libvisio'
+	'libxslt'
+	'poppler-glib'
+	'potrace'
+	'python'
+	'ttf-font'
+)
+
+optdepends=(
+	'fig2dev: xfig input'
+	'gvfs: import clip art'
+	'pstoedit: latex formulas'
+	'python-lxml: some extensions'
+	'python-numpy: some extensions'
+	'scour: optimized SVG output, some extensions'
+	'texlive-core: latex formulas'
+)
+
+#source=("https://media.inkscape.org/dl/resources/file/${pkgname}-${pkgver}.tar.bz2")
+source=("git+https://gitlab.com/inkscape/inkscape.git#commit=${_commit}")
+sha256sums=('SKIP')
+
+prepare() {
+	cd "${pkgname}"
+	git submodule init
+	git submodule update
+
+	# Fix build with glib 2.67.3
+	# https://gitlab.com/inkscape/inkscape/-/issues/2289
+	git cherry-pick -n eb24388f1730918edd9565d9e5d09340ec0b3b08
+}
+
+build() {
+	mkdir -p build
+	export PKG_CONFIG_PATH='/usr/lib/imagemagick6/pkgconfig'
+	cmake -H${pkgname} -Bbuild \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_INSTALL_PREFIX:PATH=/usr \
+		-DWITH_DBUS=ON \
+
+	cmake --build build
+}
+
+package() {
+	DESTDIR="${pkgdir}" cmake --build build --target install
+}