[arch-commits] Commit in agda/repos (2 files)

[Felix Yan]

    Date: Wednesday, May 5, 2021 @ 13:38:11
  Author: felixonmars
Revision: 927627

archrelease: copy trunk to community-staging-x86_64

Added:
  agda/repos/community-staging-x86_64/
  agda/repos/community-staging-x86_64/PKGBUILD
    (from rev 927626, agda/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: agda/repos/community-staging-x86_64/PKGBUILD (from rev 927626, agda/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-05 13:38:11 UTC (rev 927627)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=Agda
+pkgname=agda
+pkgver=2.6.1.3
+pkgrel=17
+pkgdesc="A dependently typed functional programming language and proof assistant"
+url="https://wiki.portal.chalmers.se/agda/"
+license=("custom")
+arch=('x86_64')
+depends=('ghc-libs' 'ghc' 'haskell-aeson' 'haskell-async' 'haskell-blaze-html' 'haskell-boxes'
+         'haskell-cpphs' 'haskell-data-hash' 'haskell-edit-distance' 'haskell-equivalence'
+         'haskell-geniplate-mirror' 'haskell-gitrev' 'haskell-hashable'
+         'haskell-hashtables' 'haskell-ieee754' 'haskell-murmur-hash' 'haskell-regex-tdfa'
+         'haskell-split' 'haskell-strict' 'haskell-unordered-containers' 'haskell-uri-encode'
+         'haskell-zlib')
+optdepends=('agda-stdlib: for standard library')
+makedepends=('alex' 'happy' 'ghc' 'haskell-filemanip')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('2778cde4d73bd1203690ef4bcca00fa62666a2b647f3f78525aa4f610e357663f0e03125415278870d14710916fd6e0534efd8f07cd03b4a93a37ff1ee1bbd50')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/fno-warn-overlapping-patterns/a \        , "-dynamic"' src/full/Agda/Compiler/MAlonzo/Compiler.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fcpphs -f-debug -f-enable-cluster-counting
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    LD_LIBRARY_PATH="$PWD/dist/build" runhaskell Setup copy --destdir="${pkgdir}"
+
+    # Symlink to avoid writing to this place when agda-lib is present
+    install -dm755 "$pkgdir"/usr/share/agda/lib/_build/$pkgver/agda
+    ln -s ../../../prim "$pkgdir"/usr/share/agda/lib/_build/$pkgver/agda/
+
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}