[arch-commits] Commit in haskell-floskell/repos (2 files)

[Felix Yan]

    Date: Wednesday, May 5, 2021 @ 17:13:43
  Author: felixonmars
Revision: 927799

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-floskell/repos/community-staging-x86_64/
  haskell-floskell/repos/community-staging-x86_64/PKGBUILD
    (from rev 927798, haskell-floskell/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-floskell/repos/community-staging-x86_64/PKGBUILD (from rev 927798, haskell-floskell/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-05 17:13:43 UTC (rev 927799)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=floskell
+pkgname=haskell-floskell
+pkgver=0.10.5
+pkgrel=88
+pkgdesc="A flexible Haskell source code pretty printer"
+url="https://github.com/ennocramer/floskell"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-attoparsec'
+         'haskell-data-default' 'haskell-src-exts' 'haskell-monad-dijkstra'
+         'haskell-optparse-applicative' 'haskell-unordered-containers' 'haskell-utf8-string')
+makedepends=('ghc' 'uusi' 'haskell-hspec')
+source=("https://github.com/ennocramer/floskell/archive/floskell-$pkgver.tar.gz")
+sha256sums=('91aa7caa269d1df60c7b21226721e0bd0e8595308b0d3f56dfd5e775b2d1f9ab')
+
+prepare() {
+  cd $_hkgname-floskell-$pkgver
+  uusi -u attoparsec $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-floskell-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-floskell-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-floskell-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE.md -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.md
+}