[arch-commits] Commit in rhythmbox/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Wednesday, May 5, 2021 @ 19:45:06
  Author: heftig
Revision: 414419

archrelease: copy trunk to extra-x86_64

Added:
  rhythmbox/repos/extra-x86_64/PKGBUILD
    (from rev 414416, rhythmbox/trunk/PKGBUILD)
Deleted:
  rhythmbox/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  157 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 78 insertions(+), 79 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-05-05 19:45:06 UTC (rev 414418)
+++ PKGBUILD	2021-05-05 19:45:06 UTC (rev 414419)
@@ -1,79 +0,0 @@
-# Maintainer: Jan de Groot <jgc at archlinux.org>
-# Contributor: Giovanni Scafora <giovanni at archlinux.org>
-
-pkgname=rhythmbox
-pkgver=3.4.4
-pkgrel=3
-pkgdesc="Music playback and management application"
-arch=(x86_64)
-license=(GPL)
-url="https://wiki.gnome.org/Apps/Rhythmbox"
-depends=(dconf gst-plugins-base gst-plugins-good libsoup json-glib libnotify libpeas
-         media-player-info totem-plparser tdb python-gobject libgudev grilo)
-makedepends=(itstool intltool brasero gobject-introspection vala grilo libdmapsharing lirc libgpod
-             libmtp gtk-doc yelp-tools git)
-checkdepends=(check xorg-server-xvfb)
-optdepends=('gst-plugins-ugly: Extra media codecs'
-            'gst-plugins-bad: Extra media codecs'
-            'gst-libav: Extra media codecs'
-            'brasero: Audio CD Recorder plugin'
-            'libdmapsharing: DAAP Music Sharing plugin'
-            'grilo-plugins: Grilo media browser plugin'
-            'lirc: LIRC plugin'
-            'libgpod: Portable Players - iPod plugin'
-            'libmtp: Portable Players - MTP plugin'
-            'gvfs-mtp: Portable Players - Android plugin')
-_commit=473a28752bfd6260d74f41e3b0d737f71495f4a8  # tags/v3.4.4^0
-source=("git+https://gitlab.gnome.org/GNOME/rhythmbox.git#commit=$_commit")
-sha512sums=('SKIP')
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^v//;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-
-  # https://bugs.archlinux.org/task/68537
-  git cherry-pick -n 3360f18d15cd6fabcadac56bc07d4ca133fa661f
-
-  NOCONFIGURE=1 ./autogen.sh
-}
-
-build() {
-  cd $pkgname
-  ./configure \
-    --prefix=/usr \
-    --sysconfdir=/etc \
-    --localstatedir=/var \
-    --libexecdir=/usr/lib/rhythmbox \
-    --disable-browser-plugin \
-    --disable-static \
-    --disable-more-warnings \
-    --enable-daap \
-    --enable-gtk-doc \
-    --enable-python \
-    --enable-vala \
-
-  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
-  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
-
-  make
-}
-
-check() {
-  cd $pkgname
-  glib-compile-schemas --targetdir=tests --schema-file=data/org.gnome.rhythmbox.gschema.xml
-  GSETTINGS_BACKEND=memory \
-  GSETTINGS_SCHEMA_DIR="$PWD/tests" \
-  CK_TIMEOUT_MULTIPLIER=3 \
-  xvfb-run -a -n 63 make check
-}
-
-package() {
-  cd $pkgname
-  make DESTDIR="$pkgdir" install
-  rm -r "$pkgdir/usr/lib/rhythmbox/sample-plugins"
-  rm -r "$pkgdir/usr/lib/rhythmbox/plugins/rbzeitgeist"
-}

Copied: rhythmbox/repos/extra-x86_64/PKGBUILD (from rev 414416, rhythmbox/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-05-05 19:45:06 UTC (rev 414419)
@@ -0,0 +1,78 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+
+pkgname=rhythmbox
+pkgver=3.4.4
+pkgrel=4
+pkgdesc="Music playback and management application"
+arch=(x86_64)
+license=(GPL)
+url="https://wiki.gnome.org/Apps/Rhythmbox"
+depends=(dconf gst-plugins-base gst-plugins-good libsoup json-glib libnotify
+         libpeas media-player-info totem-plparser tdb python-gobject libgudev
+         grilo)
+makedepends=(itstool intltool brasero gobject-introspection vala libdmapsharing
+             lirc libgpod libmtp zeitgeist gtk-doc yelp-tools git)
+checkdepends=(check xorg-server-xvfb)
+optdepends=('gst-plugins-ugly: Extra media codecs'
+            'gst-plugins-bad: Extra media codecs'
+            'gst-libav: Extra media codecs'
+            'brasero: Audio CD Recorder plugin'
+            'libdmapsharing: DAAP Music Sharing plugin'
+            'grilo-plugins: Grilo media browser plugin'
+            'lirc: LIRC plugin'
+            'libgpod: Portable Players - iPod plugin'
+            'libmtp: Portable Players - MTP plugin'
+            'gvfs-mtp: Portable Players - Android plugin'
+            'zeitgeist: Zeitgeist logging plugin')
+_commit=473a28752bfd6260d74f41e3b0d737f71495f4a8  # tags/v3.4.4^0
+source=("git+https://gitlab.gnome.org/GNOME/rhythmbox.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  # https://bugs.archlinux.org/task/68537
+  git cherry-pick -n 3360f18d15cd6fabcadac56bc07d4ca133fa661f
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/rhythmbox \
+    --disable-browser-plugin \
+    --disable-static \
+    --disable-more-warnings \
+    --enable-daap \
+    --enable-gtk-doc \
+    --enable-python \
+    --enable-vala \
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() (
+  cd $pkgname
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/data}"
+  export GSETTINGS_SCHEMA_DIR GSETTINGS_BACKEND=memory CK_TIMEOUT_MULTIPLIER=3
+  xvfb-run -s '-nolisten local' make check
+)
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir/usr/lib/rhythmbox/sample-plugins"
+}