[arch-commits] Commit in mlt6/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, May 6, 2021 @ 06:44:36
  Author: arojas
Revision: 414435

archrelease: copy trunk to staging-x86_64

Added:
  mlt6/repos/staging-x86_64/
  mlt6/repos/staging-x86_64/PKGBUILD
    (from rev 414434, mlt6/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: mlt6/repos/staging-x86_64/PKGBUILD (from rev 414434, mlt6/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-05-06 06:44:36 UTC (rev 414435)
@@ -0,0 +1,56 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Fabian Schoelzel <myfirstname.mylastname at googlemail.com>
+# Contributor: funkyou <spamopfer at nickname.berlin.de>
+# Contributor: tardo <tardo at nagi-fanboi.net>
+# Contributor: Stefan Husmann <stefan-husmann at t-online.de>
+# Contributor: Gustavo Alvarez <sl1pkn07 at gmail.com>
+
+pkgname=mlt6
+pkgver=6.26.1
+pkgrel=2
+pkgdesc="An open source multimedia framework"
+arch=(x86_64)
+url="https://www.mltframework.org"
+license=(GPL)
+depends=(libebur128)
+optdepends=('sdl_image: SDL1 plugin'
+            'sdl2: SDL2 plugin'
+            'libsamplerate: libavresample plugin'
+            'sox: SOX (Audio Swiss Army Knife) plugin'
+            'ffmpeg: ffmpeg plugin'
+            'vid.stab: video stabilize plugin'
+            'qt5-svg: Qt5 plugins'
+            'jack: JACK sound output plugin'
+            'ladspa: LADSPA plugins'
+            'libexif: auto rotate plugin'
+            'frei0r-plugins: for additional effects'
+            'movit: opengl plugin'
+            'opencv: openCV plugin'
+            'rubberband: rubberband plugin'
+            'gdk-pixbuf2: gdk plugin'
+            'pango: gdk plugin'
+            'rtaudio: rtaudio plugin'
+            'python: python bindings')
+makedepends=(cmake ladspa frei0r-plugins libdv sdl_image libsamplerate sox ffmpeg vid.stab qt5-svg
+             jack libexif python swig movit eigen opencv rubberband gdk-pixbuf2 pango rtaudio imagemagick)
+conflicts=(python-mlt)
+provides=(python-mlt)
+replaces=(python-mlt)
+source=($pkgname-$pkgver.tar.gz::https://github.com/mltframework/mlt/archive/v$pkgver.tar.gz)
+sha256sums=('8a484bbbf51f33e25312757531f3ad2ce20607149d20fcfcb40a3c1e60b20b4e')
+
+build() {
+  cmake -B build -S mlt-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DMOD_OPENCV=ON \
+    -DMOD_GTK2=OFF \
+    -DSWIG_PYTHON=ON
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+
+  mv "$pkgdir"/usr/bin/melt{,6} # Fix conflicts with mlt 7
+}