[arch-commits] Commit in (svt-av1 svt-av1/trunk svt-av1/trunk/PKGBUILD)

[Maxime Gauduin]

    Date: Thursday, May 6, 2021 @ 09:52:55
  Author: alucryd
Revision: 414492

move svt-av1 to extra for ffmpeg

Added:
  svt-av1/
  svt-av1/trunk/
  svt-av1/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: svt-av1/trunk/PKGBUILD
===================================================================
--- svt-av1/trunk/PKGBUILD	                        (rev 0)
+++ svt-av1/trunk/PKGBUILD	2021-05-06 09:52:55 UTC (rev 414492)
@@ -0,0 +1,49 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Daniel Bermond <dbermond at archlinux.org>
+# Contributor: Thomas Schneider <maxmusterm at gmail.com>
+
+pkgname=svt-av1
+pkgver=0.8.6
+pkgrel=3
+pkgdesc='Scalable Video Technology AV1 encoder and decoder'
+arch=(x86_64)
+url=https://gitlab.com/AOMediaCodec/SVT-AV1
+license=(
+  BSD
+  'custom: Alliance for Open Media Patent License 1.0'
+)
+depends=(glibc)
+makedepends=(
+  cmake
+  git
+  nasm
+  ninja
+)
+_tag=a5ec26c0f0bd6e872a0b2bb340b4a777f4847020
+source=(git+https://gitlab.com/AOMediaCodec/SVT-AV1.git#tag=${_tag})
+b2sums=(SKIP)
+
+prepare() {
+  sed '/CMAKE_BUILD_TYPE Release/d' -i SVT-AV1/CMakeLists.txt
+}
+
+pkgver() {
+  cd SVT-AV1
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  export LDFLAGS="$LDFLAGS -Wl,-z,noexecstack"
+  cmake -S SVT-AV1 -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_SHARED_LIBS=ON \
+    -DNATIVE=OFF
+  ninja -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -Dm 644 SVT-AV1/{LICENSE,PATENTS}.md -t "${pkgdir}"/usr/share/licenses/svt-av1/
+}
+
+# vim: ts=2 sw=2 et: