[arch-commits] Commit in jose/trunk (PKGBUILD)

[Jonas Witschel]

    Date: Friday, May 7, 2021 @ 17:26:23
  Author: diabonas
Revision: 928648

upgpkg: jose 11-1: upstream release

- Upstream switched the build system from Autotools to Meson.
- Build from signed Git commit, PGP key is the same as for Clevis and Tang.

Modified:
  jose/trunk/PKGBUILD

----------+
 PKGBUILD |   30 +++++++++++++++++++-----------
 1 file changed, 19 insertions(+), 11 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2021-05-07 17:24:24 UTC (rev 928647)
+++ PKGBUILD	2021-05-07 17:26:23 UTC (rev 928648)
@@ -1,27 +1,35 @@
 # Maintainer: Jonas Witschel <diabonas at archlinux.org>
 pkgname=jose
-pkgver=10
-pkgrel=3
+pkgver=11
+_commit=145c41a4ec70c15f6f8aa12a915e16cb60f0991f # git rev-parse "v$pkgver^{}"
+pkgrel=1
 pkgdesc='C-language implementation of Javascript Object Signing and Encryption'
 arch=('x86_64')
 url='https://github.com/latchset/jose'
 license=('APACHE')
 depends=('jansson' 'openssl' 'zlib')
-source=("$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.bz2")
-sha512sums=('596f71bf7f3ab65164556d8353c07a09283e80ad06f8cbb7b1a9609fe3c95888c94c032ae8d719ed3f3b361cb87188f4683728e649d454056841b8ca47828b9d')
+makedepends=('git' 'asciidoc' 'meson')
+source=("git+$url.git?signed#commit=$_commit")
+sha512sums=('SKIP')
+validpgpkeys=('7CE2CB3D2AF59FE1EA22F551D0D219ED1F7E762C') # Sergio Correia <scorreia at redhat.com>
 
+pkgver() {
+	cd "$pkgname"
+	git describe --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
+}
+
 build() {
-	cd "$pkgname-$pkgver"
-	./configure --prefix=/usr
-	make
+	cd "$pkgname"
+	meson --prefix=/usr --buildtype=plain build
+	meson compile -C build
 }
 
 check() {
-	cd "$pkgname-$pkgver"
-	make check
+	cd "$pkgname"
+	meson test -C build
 }
 
 package() {
-	cd "$pkgname-$pkgver"
-	make DESTDIR="$pkgdir" install
+	cd "$pkgname"
+	DESTDIR="$pkgdir" meson install -C build
 }