[arch-commits] Commit in qgis/repos (4 files)

[Evangelos Foutras]

    Date: Saturday, May 8, 2021 @ 12:46:22
  Author: foutrelis
Revision: 928822

archrelease: copy trunk to community-staging-x86_64

Added:
  qgis/repos/community-staging-x86_64/
  qgis/repos/community-staging-x86_64/PKGBUILD
    (from rev 928821, qgis/trunk/PKGBUILD)
  qgis/repos/community-staging-x86_64/qgis-proj8.patch
    (from rev 928821, qgis/trunk/qgis-proj8.patch)
  qgis/repos/community-staging-x86_64/qgis-qwtpolar-link.patch
    (from rev 928821, qgis/trunk/qgis-qwtpolar-link.patch)

--------------------------+
 PKGBUILD                 |   55 +++++++++++++++++++++++++++++++++++++++++++++
 qgis-proj8.patch         |   29 +++++++++++++++++++++++
 qgis-qwtpolar-link.patch |   12 +++++++++
 3 files changed, 96 insertions(+)

Copied: qgis/repos/community-staging-x86_64/PKGBUILD (from rev 928821, qgis/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-08 12:46:22 UTC (rev 928822)
@@ -0,0 +1,55 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Doug Newgard <scimmia at archlinux dot org>
+# Contributor: XavierCLL <xavier.corredor.llano (a) gmail.com>
+# Contributor: SaultDon <sault.don gmail>
+# Contributor: Lantald < lantald at gmx.com >
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: dibblethewrecker dibblethewrecker.at.jiwe.dot.org
+# Contributor: Gerardo Exequiel Pozzi <vmlinuz386 at yahoo.com.ar>
+# Contributor: Eric Forgeot < http://esclinux.tk >
+
+pkgname=qgis
+pkgver=3.18.2
+pkgrel=3
+pkgdesc='Geographic Information System (GIS) that supports vector, raster & database formats'
+url='https://qgis.org/'
+license=('GPL')
+arch=('x86_64')
+depends=('exiv2' 'gdal' 'gsl' 'hicolor-icon-theme' 'libzip' 'ocl-icd' 'pdal' 'protobuf'
+         'python-gdal' 'python-jinja' 'python-owslib' 'python-psycopg2' 'python-pygments'
+         'python-qscintilla-qt5' 'python-sip4' 'python-yaml' 'qca' 'qt5-3d' 'qt5-imageformats'
+         'qt5-serialport' 'qt5-webkit' 'qtkeychain-qt5' 'qwtpolar' 'spatialindex')
+makedepends=('cmake' 'fcgi' 'ninja' 'opencl-clhpp' 'python-setuptools' 'python-six' 'qt5-tools'
+             'txt2tags' 'sip4')
+optdepends=('fcgi: Map server'
+            'gpsbabel: GPS Tools plugin')
+source=("https://qgis.org/downloads/$pkgname-$pkgver.tar.bz2"
+        'qgis-qwtpolar-link.patch'
+        'qgis-proj8.patch')
+sha256sums=('1913e4d5596bbc8b7d143f3defb18bf376f750a71f334f69d76af5deca7ecc5d'
+            'd4c1e7bad45186822348a3a7f0951a8253506c69075bd2ead090ae017cd26af4'
+            '58f58b5e43cc9f13b55bf2a9742b3c7cb555eee3c4075611980f0496cfd24c89')
+
+prepare() {
+  patch -d $pkgname-$pkgver -p1 < qgis-qwtpolar-link.patch # https://github.com/qgis/QGIS/issues/41910
+  patch -d $pkgname-$pkgver -p1 < qgis-proj8.patch # https://github.com/qgis/QGIS/issues/41735
+}
+
+build() {
+  cmake -S $pkgname-$pkgver -B build -G Ninja \
+    -DCMAKE_INSTALL_PREFIX='/usr' \
+    -DWITH_3D=TRUE \
+    -DWITH_SERVER=TRUE \
+    -DWITH_CUSTOM_WIDGETS=TRUE \
+    -DBINDINGS_GLOBAL_INSTALL=TRUE \
+    -DQGIS_MANUAL_SUBDIR=share/man \
+    -DWITH_QWTPOLAR=TRUE \
+    -DWITH_INTERNAL_QWTPOLAR=FALSE \
+    -DWITH_PDAL=TRUE
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 $pkgname-$pkgver/rpm/sources/qgis-mime.xml "$pkgdir/usr/share/mime/packages/qgis.xml"
+}

Copied: qgis/repos/community-staging-x86_64/qgis-proj8.patch (from rev 928821, qgis/trunk/qgis-proj8.patch)
===================================================================
--- community-staging-x86_64/qgis-proj8.patch	                        (rev 0)
+++ community-staging-x86_64/qgis-proj8.patch	2021-05-08 12:46:22 UTC (rev 928822)
@@ -0,0 +1,29 @@
+From fc1ac8bef8dcc3194857ecd32519aca4867b4fa1 Mon Sep 17 00:00:00 2001
+From: Bas Couwenberg <sebastic at xs4all.nl>
+Date: Tue, 23 Feb 2021 18:40:14 +0100
+Subject: [PATCH] Add support for PROJ 8.0.0 in FindProj.cmake.
+
+proj_api.h is no longer available in PROJ 8.0.0, use proj.h instead.
+
+Fixes: #41735
+---
+ cmake/FindProj.cmake | 6 ++++++
+ 1 file changed, 6 insertions(+)
+
+diff --git a/cmake/FindProj.cmake b/cmake/FindProj.cmake
+index 0afee15fd14c..ccfaf13d9edf 100644
+--- a/cmake/FindProj.cmake
++++ b/cmake/FindProj.cmake
+@@ -40,6 +40,12 @@ FIND_PATH(PROJ_INCLUDE_DIR proj_api.h
+   "$ENV{INCLUDE}"
+   "$ENV{LIB_DIR}/include"
+   )
++IF (NOT PROJ_INCLUDE_DIR)
++  FIND_PATH(PROJ_INCLUDE_DIR proj.h
++    "$ENV{INCLUDE}"
++    "$ENV{LIB_DIR}/include"
++    )
++ENDIF (NOT PROJ_INCLUDE_DIR)
+ 
+ FIND_LIBRARY(PROJ_LIBRARY NAMES proj_i proj PATHS
+   "$ENV{LIB}"

Copied: qgis/repos/community-staging-x86_64/qgis-qwtpolar-link.patch (from rev 928821, qgis/trunk/qgis-qwtpolar-link.patch)
===================================================================
--- community-staging-x86_64/qgis-qwtpolar-link.patch	                        (rev 0)
+++ community-staging-x86_64/qgis-qwtpolar-link.patch	2021-05-08 12:46:22 UTC (rev 928822)
@@ -0,0 +1,12 @@
+diff --git a/src/app/CMakeLists.txt b/src/app/CMakeLists.txt
+index 072e40a9bb..02dcd9795e 100644
+--- a/src/app/CMakeLists.txt
++++ b/src/app/CMakeLists.txt
+@@ -494,6 +494,7 @@ target_link_libraries(qgis_app
+   ${OPTIONAL_QTWEBKIT}
+   #should only be needed for win
+   ${QT_QTMAIN_LIBRARY}
++  ${QWTPOLAR_LIBRARY}
+   qgis_core
+   qgis_gui
+   qgis_analysis