[arch-commits] Commit in mutter/repos (3 files)

Jan Steffens heftig at archlinux.org
Mon May 10 07:18:22 UTC 2021


    Date: Monday, May 10, 2021 @ 07:18:21
  Author: heftig
Revision: 414899

archrelease: copy trunk to testing-x86_64

Added:
  mutter/repos/testing-x86_64/
  mutter/repos/testing-x86_64/PKGBUILD
    (from rev 414897, mutter/trunk/PKGBUILD)
  mutter/repos/testing-x86_64/mutter.install
    (from rev 414897, mutter/trunk/mutter.install)

----------------+
 PKGBUILD       |   69 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 mutter.install |    7 +++++
 2 files changed, 76 insertions(+)

Copied: mutter/repos/testing-x86_64/PKGBUILD (from rev 414897, mutter/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-05-10 07:18:21 UTC (rev 414899)
@@ -0,0 +1,69 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Michael Kanis <mkanis_at_gmx_dot_de>
+
+pkgname=mutter
+pkgver=40.0+103+ga49dc7839
+pkgrel=1
+pkgdesc="A window manager for GNOME"
+url="https://gitlab.gnome.org/GNOME/mutter"
+arch=(x86_64)
+license=(GPL)
+depends=(dconf gobject-introspection-runtime gsettings-desktop-schemas
+         libcanberra startup-notification zenity libsm gnome-desktop upower
+         libxkbcommon-x11 gnome-settings-daemon libgudev libinput pipewire
+         xorg-xwayland graphene libxkbfile)
+makedepends=(gobject-introspection git egl-wayland meson xorg-server)
+checkdepends=(xorg-server-xvfb pipewire-media-session)
+provides=(libmutter-8.so)
+groups=(gnome)
+install=mutter.install
+_commit=a49dc78396bda45da43ac111ffdceeca2892800d  # master
+source=("git+https://gitlab.gnome.org/GNOME/mutter.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
+  LDFLAGS+=" -Wl,-Bsymbolic-functions"
+  arch-meson $pkgname build \
+    -D egl_device=true \
+    -D wayland_eglstream=true \
+    -D installed_tests=false \
+    -D profiler=false
+  meson compile -C build
+}
+
+_check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/data}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+
+  pipewire &
+  _p1=$!
+
+  pipewire-media-session &
+  _p2=$!
+
+  trap "kill $_p1 $_p2; wait" EXIT
+
+  meson test -C build --print-errorlogs
+)
+
+check() {
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local +iglx -noreset' \
+    bash -c "$(declare -f _check); _check"
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: mutter/repos/testing-x86_64/mutter.install (from rev 414897, mutter/trunk/mutter.install)
===================================================================
--- testing-x86_64/mutter.install	                        (rev 0)
+++ testing-x86_64/mutter.install	2021-05-10 07:18:21 UTC (rev 414899)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/mutter
+}
+
+post_upgrade() {
+  post_install
+}



More information about the arch-commits mailing list