[arch-commits] Commit in gnome-shell/repos (3 files)

[Jan Steffens]

    Date: Monday, May 10, 2021 @ 07:18:21
  Author: heftig
Revision: 414898

archrelease: copy trunk to testing-x86_64

Added:
  gnome-shell/repos/testing-x86_64/
  gnome-shell/repos/testing-x86_64/PKGBUILD
    (from rev 414897, gnome-shell/trunk/PKGBUILD)
  gnome-shell/repos/testing-x86_64/gnome-shell.install
    (from rev 414897, gnome-shell/trunk/gnome-shell.install)

---------------------+
 PKGBUILD            |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++
 gnome-shell.install |    7 +++++
 2 files changed, 67 insertions(+)

Copied: gnome-shell/repos/testing-x86_64/PKGBUILD (from rev 414897, gnome-shell/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-05-10 07:18:21 UTC (rev 414898)
@@ -0,0 +1,60 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Flamelab <panosfilip at gmail.com
+
+pkgname=gnome-shell
+pkgver=40.0+80+ga08355931
+pkgrel=1
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+arch=(x86_64)
+license=(GPL)
+depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gtk4
+         gnome-settings-daemon gnome-themes-extra gsettings-desktop-schemas
+         libcanberra-pulse libgdm libsecret mutter nm-connection-editor unzip
+         gstreamer libibus gnome-autoar gnome-disk-utility gst-plugin-pipewire)
+makedepends=(gtk-doc gnome-control-center evolution-data-server
+             gobject-introspection git meson sassc asciidoc bash-completion)
+checkdepends=(xorg-server-xvfb)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome)
+install=gnome-shell.install
+_commit=a08355931f40bb0ee6a6989e373757d39dea63cb  # master
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  meson compile -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  export XDG_RUNTIME_DIR
+
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local +iglx -noreset' \
+  meson test -C build --print-errorlogs
+)
+
+package() {
+  depends+=(libmutter-8.so)
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: gnome-shell/repos/testing-x86_64/gnome-shell.install (from rev 414897, gnome-shell/trunk/gnome-shell.install)
===================================================================
--- testing-x86_64/gnome-shell.install	                        (rev 0)
+++ testing-x86_64/gnome-shell.install	2021-05-10 07:18:21 UTC (rev 414898)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/gnome-shell
+}
+
+post_upgrade() {
+  post_install
+}